www.gusucode.com > ASP+ACCESS学生论坛设计与实现(源代码+论文+开题报告) > ASP+ACCESS学生论坛设计与实现(源代码+论文+开题报告)\13学生论坛ASPAC\BBS\bbseven.asp

    <!--#include file="conn.asp"-->
<!-- #include file="inc/const.asp" -->
<!-- #include file="inc/dv_clsother.asp" -->
<%
Mybbs.LoadTemplates("paper_even_toplist")
Dim Rs,sql,i,isshow
isshow=False
If Mybbs.BoardID=0 then
	Mybbs.stats=template.Strings(4)
	Mybbs.nav()
	Mybbs.Head_var 2,0,"",""
Else
	Mybbs.stats=template.Strings(5)
	Mybbs.nav()
	Mybbs.Head_var 1,Mybbs.Board_Data(4,0),"",""
End If

If Cint(Mybbs.GroupSetting(39))=0  And Not Mybbs.master Then Mybbs.AddErrCode(55)
Mybbs.ShowErr

boardeven()

Mybbs.activeonline()
Mybbs.footer()

Sub boardeven()
	Dim currentpage,page_count,Pcount
	Dim endpage
	Dim totalrec
	totalrec=0
	currentPage=request("page")
	If currentpage="" Or Not IsNumeric(currentpage) Then
		currentpage=1
	Else
		currentpage=clng(currentpage)
	End If
	Dim TempStr,TempStr1,TempStr2,TempStr3
	Dim TempArray
	TempStr = template.html(5)
	TempArray = Split(template.html(6),"||")
	TempStr2 = TempArray(1)

	Set Rs=Server.CreateObject("ADODB.RecordSet")
	If Mybbs.BoardID>0 Then
		sql="select * from dv_log where l_boardid="&Mybbs.BoardID&" and l_type >2 order by l_addtime desc"
	Else
		sql="select * from dv_log where l_type > 2 order by l_addtime desc"
	End If
	If Not IsObject(Conn) Then ConnectionDatabase
	Rs.Open sql,conn,1,1
	If rs.bof And rs.eof Then
		TempStr1 = TempArray(0)
	Else
		chkshow()
		rs.PageSize = Mybbs.Forum_Setting(11)
		rs.AbsolutePage=currentpage
		page_count=0
		totalrec=rs.recordcount
		While (Not rs.eof) And (Not page_count = rs.PageSize)
			TempArray = rs("l_touser") & "||" & rs("l_content") & "||" & rs("l_username")
			TempArray = Mybbs.HtmlEncode(TempArray)
			TempArray = Split(TempArray,"||")
			TempStr3 = TempStr2
			TempStr3 = Replace(TempStr3,"{$username}",TempArray(0))
			TempStr3 = Replace(TempStr3,"{$content}",TempArray(1))
			TempStr3 = Replace(TempStr3,"{$addtime}",rs("l_addtime"))
			If isshow or Mybbs.MemberName=rs("l_username") Then
				TempStr3 = Replace(TempStr3,"{$postuser}","<a href=dispuser.asp?name="&TempArray(2)&" target=_blank>"&TempArray(2)&"</a>")
			Else
				TempStr3 = Replace(TempStr3,"{$postuser}","保密")
			End If
			TempStr1 = TempStr1 & TempStr3
			page_count = page_count + 1
		Rs.Movenext
		Wend
	End If

  	If totalrec Mod Mybbs.Forum_Setting(11)=0 Then
     		Pcount= totalrec \ Mybbs.Forum_Setting(11)
  	Else
     		Pcount= totalrec \ Mybbs.Forum_Setting(11)+1
  	End If
	TempStr = Replace(TempStr,"{$evenloop}",TempStr1)
	TempStr = Replace(TempStr,"{$pagelist}",template.html(3))
	TempStr = Replace(TempStr,"{$page}",currentpage)
	TempStr = Replace(TempStr,"{$Pcount}",Pcount)
	TempStr = Replace(TempStr,"{$width}",Mybbs.mainsetting(0))
	TempStr = Replace(TempStr,"{$alertcolor}",Mybbs.mainsetting(1))
	TempStr = Replace(TempStr,"{$pagelimited}",Mybbs.Forum_Setting(11))
	TempStr = Replace(TempStr,"{$listnum}",totalrec)
	TempStr = Replace(TempStr,"{$boardid}",Mybbs.BoardID)
	Response.Write TempStr

	Rs.Close
	Set Rs=Nothing
	
End Sub
Sub chkshow()
	If Mybbs.master or Mybbs.superboardmaster  Then
		isshow=True
	ElseIf Mybbs.BoardID<>0 Then 
		If Mybbs.Board_Setting(36)<>"" and IsNumeric(Mybbs.Board_Setting(36)) Then
			If Cint(Mybbs.Board_Setting(36))=1  Then
				isshow=True
			Else
				isshow=False 
			End If
		End If
	Else
		isshow=False 
	End If
End Sub
%>