www.gusucode.com > ASP+ACCESS学生论坛设计与实现(源代码+论文+开题报告) > ASP+ACCESS学生论坛设计与实现(源代码+论文+开题报告)\13学生论坛ASPAC\BBS\dispbbs.asp

    <!--#include file="conn.asp"-->
<!--#include file="inc/const.asp"-->
<!--#include file="inc/dv_clsother.asp"-->
<!--#include file="inc/dv_ubbcode.asp"-->
<!--#include file="inc/ubblist.asp"-->
<%
If Mybbs.BoardID = 0 Then
	Response.Write "参数错误"
	Response.End 
End If
Mybbs.LoadTemplates("dispbbs")
Dim AnnounceID,ReplyID,Star,Skin,followup
Dim CanReply,IsTop,IsVote,TopicCount,PollID,TotaluseTable,ViewNum,Topic,TopicMode
Dim PostBuyUser,abgcolor,bgcolor,UserName
Chk_Topic_Err
Mybbs.Showerr()
Mybbs.Nav()
Mybbs.Showerr()
Mybbs.Head_var 1,Mybbs.Board_Data(4,0),"",""
Mybbs.ActiveOnline()
Dim Page,LockTopic
Dim action
Dim TopicNum,n,SplitPageNum
Dim EmotPath
EmotPath=Split(Mybbs.Forum_emot,"|||")(0)		'em心情路径
action=Request("action")
Page=Request("Page")
If isNumeric(Page) = 0 or Page="" Then Page=1
Page=Clng(Page)
Show_Topic_Top()
Mybbs.ShowErr()
Dim dv_ubb
Set dv_ubb=new Dvbbs_UbbCode
Show_Topic_Body
Set dv_ubb=Nothing
If Skin=1 Then showtree()
If CanReply Then Show_Topic_FastRe
If Mybbs.UserID>0 Then Show_Topic_ManageAction
Mybbs.NewPassword()
Mybbs.Footer()

Function Chk_Topic_Err
	AnnounceID=Request("ID")
	If AnnounceID="" Or Not IsNumeric(AnnounceID) Then Mybbs.AddErrCode(30)
	ReplyID=Request("ReplyID")
	If ReplyID="" Or Not IsNumeric(ReplyID) Then ReplyID=AnnounceID
	Star=Request("Star")
	If Star="" Or Not IsNumeric(Star) Then Star=1
	Star=Clng(Star)
	Skin=Request("Skin")
	If Skin="" Or Not IsNumeric(Skin) Then Skin=Mybbs.Board_setting(24)
	If Mybbs.ErrCodes<>"" Then Exit Function
	Dim BrowserType
	Set BrowserType=New Cls_Browser
	If BrowserType.IsSearch Then Response.redirect "printpage.asp?BoardID="&Mybbs.BoardID&"&ID="&AnnounceID
	Set BrowserType=Nothing
	Dim SQl,Rs
	Dim MyCanReply
	Set Rs=Server.CreateObject("Adodb.RecordSet")
	SQL="Select title,istop,isbest,PostUserName,PostUserid,hits,isvote,child,pollid,LockTopic,PostTable,BoardID,TopicMode from dv_topic where topicID="&Announceid
	If Not IsObject(Conn) Then ConnectionDatabase
	Rs.Open SQL,Conn,1,3
	Mybbs.SqlQueryNum=Mybbs.SqlQueryNum+1
	'Set Rs=Mybbs.Execute(SQL)
	If Not(Rs.BOF and Rs.EOF) then
		If Rs(11)<>Mybbs.BoardID Then Mybbs.AddErrCode(29)
		Rs(5)=Rs(5)+1
		Rs.Update
		Topic=Rs(0)
		istop=rs(1)
		isVote=rs(6)
		TopicCount=rs(7)+1
		pollid=rs(8)
		Locktopic=rs(9)
		TotalUseTable=rs(10)
		TopicMode=rs(12)
		ViewNum=Rs(5)
		If rs(3)=Mybbs.Membername then
			MyCanReply=Mybbs.GroupSetting(4)
		Else
			MyCanReply=Mybbs.GroupSetting(5)
			If Cint(Mybbs.GroupSetting(2))=0 Then Mybbs.AddErrcode(31)
		End If
		If Len(Topic) > Cint(Mybbs.Board_Setting(25)) And Not TopicMode>0 Then
			Topic=Left(Topic,Mybbs.Board_Setting(25))&"..."
		End If
		If TopicMode>0 Then
			If TopicMode=1 Then
				Topic = Replace(Topic,"<!--","&lt;!--")		
			Else
				Topic = Replace(Topic,"<","&lt;")
				Topic = Replace(Topic,">","&gt;")	
				Topic=Dvbbs_TopicMode(Topic,TopicMode)
			End If
		Else
			Topic = Replace(Topic,"<","&lt;")
			Topic = Replace(Topic,">","&gt;")
		End If
		Topic=Mybbs.ChkBadWords(Topic)
		Mybbs.Stats=Topic
	Else
		Mybbs.AddErrcode(32)
	End If
	Rs.Close
	Set Rs=Nothing
	CanReply=False
	If (Not Mybbs.Board_Setting(0)="1" And Cint(mycanreply)=1 And Cint(locktopic)=0) Or (Mybbs.master Or Mybbs.superboardmaster Or Mybbs.boardmaster) Then
		CanReply=True
	End If
End Function

Function Show_Topic_Top()
	 
	Dim TempStr,MyTempStr
	If (Mybbs.Board_Setting(43)="0" And Mybbs.Board_Setting(0)="0") Or (Mybbs.Board_Setting(43)="0" And Mybbs.Board_Setting(0)="1" And (Mybbs.Master Or Mybbs.SuperBoardMaster Or Mybbs.BoardMaster)) Then
		MyTempStr=Split(template.html(1),"||")
		TempStr=Replace(MyTempStr(0),"{$pic_newpost}",Mybbs.mainpic(7))
		TempStr=Replace(TempStr,"{$pic_newvote}",Mybbs.mainpic(8))
		If Mybbs.Forum_ChanSetting(0)=1 And Mybbs.Forum_ChanSetting(7)=1 Then
			TempStr=TempStr & MyTempStr(1)
		End If
	Else
		If Mybbs.Board_Setting(0)="1" Then TempStr=template.Strings(0)
	End If
	TempStr=Replace(template.html(0),"{$topicpostinfo}",TempStr)
	TempStr=Replace(TempStr,"{$width}",Mybbs.mainsetting(0))
	TempStr=Replace(TempStr,"{$boardid}",Mybbs.BoardID)
	TempStr=Replace(TempStr,"{$page}",page)
	TempStr=Replace(TempStr,"{$replyid}",ReplyID)
	TempStr=Replace(TempStr,"{$star}",Star)
	TempStr=Replace(TempStr,"{$announceid}",AnnounceID)
	TempStr=Replace(TempStr,"{$viewnum}",ViewNum)
	Dim Skinpic,Skinname,nskin
	If Skin="1" Then
		nskin=0
		Skinpic=template.pic(1)
		Skinname=template.Strings(2)
	Else
		nskin=1
		Skinpic=template.pic(0)
		Skinname=template.Strings(1)
	End If
	TempStr=Replace(TempStr,"{$skin}",nskin)
	TempStr=Replace(TempStr,"{$skinname}",skinname)
	TempStr=Replace(TempStr,"{$skinpic}",skinpic)
	TempStr=Replace(TempStr,"{$topic}",Topic)
	If IsVote=1 Then
		TempStr=Replace(TempStr,"{$voteinfo}",Show_Topic_Vote)
	Else
		TempStr=Replace(TempStr,"{$voteinfo}","")
	End If
	Response.Write TempStr
End Function

Function Show_Topic_Body()
	If UBound(Mybbs.Forum_ads)>13 Then 
		Mybbs.Forum_ads(14)=Split(Mybbs.Forum_ads(14),vbNewLine)
	End If
	Dim SQL,Rs,i
	Dim TopicPageList,Pcount
	Dim layer
	TopicPageList=Mybbs.Board_Setting(27)
	With Response
	.Write "<Script Language=JavaScript>"
	.Write  template.html(4)
	.Write  "var TempStr='"&Replace(Replace(Replace(Replace(Replace(template.html(2),"{$boardtype}",Server.Htmlencode(Mybbs.Board_Data(1,0))),"\","\\"),"'","\'"),VbCrLf,"\n"),chr(13),"")&"';"
	.Write  "var sTempStr='"&Replace(Replace(Replace(Replace(template.html(3),"\","\\"),"'","\'"),VbCrLf,"\n"),chr(13),"")&"';"
	.Write  "sTempStr=sTempStr.split(""||"");"
	.Write  "var alertcolor='"&Mybbs.mainsetting(1)&"';"
	.Write  "var Board_Setting27='"&TopicPageList&"';"
	.Write  "var fontsize='"&Mybbs.Board_Setting(28)&"';"
	.Write  "var lineheight='"&Mybbs.Board_Setting(29)&"';"
	.Write  "var Forum_Setting42='"&Mybbs.Forum_Setting(42)&"';"
	.Write  "var facesetting='"&Mybbs.Forum_Setting(53)&"';"
	.Write  "var votemoney='"&Mybbs.GroupSetting(47)&"';"
	.Write  "var Forum_ChanSetting0='"&Mybbs.Forum_ChanSetting(0)&"';"
	.Write  "var Forum_ChanSetting5='"&Mybbs.Forum_ChanSetting(5)&"';"
	.Write  "var Forum_ChanSetting6='"&Mybbs.Forum_ChanSetting(6)&"';"
	.Write  "var Forum_ChanSetting7='"&Mybbs.Forum_ChanSetting(7)&"';"
	.Write  "var topfloor='"&template.Strings(3)&"';"
	.Write  "var floor='"&template.Strings(4)&"';"
	.Write  "var lockuserinfo1='"&template.Strings(5)&"';"
	.Write  "var lockuserinfo2='"&template.Strings(7)&"';"
	.Write  "var noviewbest='"&template.Strings(6)&"';"
	.Write  "var actioninfo1='"&template.Strings(8)&"';"
	.Write  "var actioninfo2='"&template.Strings(9)&"';"
	.Write  "var GroupSetting41='"&Mybbs.GroupSetting(41)&"';"
	.Write  "var TopicMode='"&TopicMode&"';"
	.Write  "var mainsetting='"&Mybbs.mainhtml(0)&"';"
	.Write  "var mainsetting=mainsetting.split(""||"");"
	.Write  "var TopicNum='"&TopicCount&"';"
	.Write  "</Script>"
	SQL="B.AnnounceID,B.BoardID,B.UserName,B.Topic,B.dateandtime,B.body,B.Expression,B.ip,B.RootID,B.signflag,B.isbest,B.PostUserid,B.layer,b.isagree,U.useremail,U.UserIM,U.UserMobile,U.Usersign,U.userclass,U.Usertitle,U.Userwidth,U.Userheight,U.UserPost,U.Userface,U.JoinDate,U.userWealth,U.userEP,U.userCP,U.Userbirthday,U.Usersex,u.UserGroup,u.LockUser,u.userPower,U.titlepic,U.UserGroupID,U.LastLogin,B.PostBuyUser,U.UserHidden,U.IsChallenge,B.Ubblist,B.LockTopic"
	If cint(skin)=1 and Clng(replyid)=Clng(Announceid) Then
		SQL="Select top 1 "&SQL&" From "&TotalUseTable&" B Inner Join [dv_user] U On U.UserID=B.PostUserID Where B.BoardID="&Mybbs.BoardID&" And B.RootID="&AnnounceID&"  Order By B.AnnounceID, B.DateAndTime"
	ElseIf cint(skin)=1 Then
		SQL="Select "&SQL&" From "&TotalUseTable&" B Inner Join [dv_user] U On U.UserID=B.PostUserID Where B.BoardID="&Mybbs.BoardID&" And B.AnnounceID="&replyID
	Else
		Dim AnnounceIDlists
		AnnounceIDlists=AnnounceIDlist()
		SQL="Select "&SQL&" From "&TotalUseTable&" B Inner Join [dv_user] U On U.UserID=B.PostUserID Where B.RootID="&Announceid&" And B.BoardID="&Mybbs.BoardID&" And  B.AnnounceID in ("&AnnounceIDlists&") Order BY B.AnnounceID, B.DateAndTime"
	End If
	Set Rs =Mybbs.Execute(SQL)
	If Rs.EOF And Rs.BOF Then
		Mybbs.AddErrCode(33)
		Exit Function
	End If

	If Not(Rs.EOF And Rs.BOF) Then
		followup = Rs("AnnounceID")
		If TopicCount mod Cint(TopicPageList)=0 then
			Pcount= TopicCount \ Cint(TopicPageList)
		Else
			Pcount= TopicCount \ Cint(TopicPageList)+1
		End If
		'Rs.MoveFirst
		If star > Pcount Then star = Pcount
		If star < 1 Then star = 1				
		'If Cint(skin) <> 1 Then Rs.Move (star-1) * TopicPageList
		.Write "<Script Language=JavaScript>"
		.Write  "var star='"&star&"';"
		.Write  "</Script>"
		'AnnounceID=0,BoardID=1,UserName=2,Topic=3,dateandtime=4,body=5,
		'Expression=6,ip=7,RootID=8,signflag=9,isbest=10,PostUserid=11,
		'layer=12,isagree=13,useremail=14,UserIM=15,UserMobile=16,sign=17,
		'userclass=18,title=19,width=20,height=21,article=22,face=23,JoinDate=24,
		'userWealth=25,userEP=26,userCP=27,birthday=28,sex=29,UserGroup=30,LockUser=31,
		'userPower=32,titlepic=33,UserGroupID=34,LastLogin=35,PostBuyUser=36,Ubblists=39,LockTopic=40
		Dim k,rndnum,TopicAddata,Topic_Ads,UserSign,TopicBody
		K=0
		Dim MyTempStr,ReplaceStr
		SQL=Rs.GetRows(TopicPageList)
		Set Rs=Nothing
		For i=0 To Ubound(SQL,2)
			.Write "<a name="&SQL(0,i)&"></a>"
			.Write "<Script Language=JavaScript>"
			UserName=Mybbs.HtmlEncode(SQL(2,i))
			If SQL(40,i)=2 Then
				.Write "var actioninfo3='"&template.Strings(16)&"';"
			Else
				.Write "var actioninfo3='"&template.Strings(15)&"';"
			End If
			If bgcolor="tablebody1" Then
				bgcolor="tablebody2"
				abgcolor="tablebody1"
			Else
				bgcolor="tablebody1"
				abgcolor="tablebody2"
			End If
			ReplyID=SQL(0,i)
			PostBuyUser=SQL(36,i)
			Topic_Ads=""
			If Mybbs.Forum_ChanSetting(5)="1" Then
				If Mybbs.Forum_AdLoop3<>"" Then
					Randomize
					rndnum=Cint((i3-1)*rnd+1)
					If rndnum=0 Then rndnum=1
					TopicAddata=Ad_3(rndnum-1)
					TopicAddata=Replace(Replace(TopicAddata,"\","\\"),"'","\'")
					Topic_Ads=TopicAddata
					TopicAddata=""
				Else
					Topic_Ads=""
				End If
			Else
				If UBound(Mybbs.Forum_ads)>13 Then
					If Topic_Ads="" And UBound(Mybbs.Forum_ads(14)) > -1 Then
						Randomize
						Topic_Ads=Mybbs.Forum_ads(14)(CInt(UBound(Mybbs.Forum_ads(14))*Rnd))
						Topic_Ads= Replace(Replace(Topic_Ads,"\","\\"),"'","\'")
					End If
				Else
					Topic_Ads=""
				End If
			End If	
			UserSign=""
			If Not Isnull(SQL(17,i)) Or Not SQL(17,i)="" Then
				If SQL(9,i)=1 and SQL(31,i)=0 and Cint(Mybbs.forum_setting(42))=1 Then
					UserSign = dv_ubb.Dv_SignUbbCode(SQL(17,i),SQL(34,i))
					UserSign=Replace(Replace(UserSign,"\","\\"),"'","\'")
					'UserSign = Replace(UserSign, vbNewLine,"\n")
				End If
			End If
			Ubblists=SQL(39,i)
			If Not (SQL(31,i)=2 Or (SQL(10,i)=1 And CInt(Mybbs.GroupSetting(41))=0) Or SQL(31,i)=1) Then
				If InStr(Ubblists,",39,") > 0  Then
					TopicBody = dv_ubb.Dv_UbbCode(SQL(5,i),SQL(34,i),1,0)
				Else
					TopicBody = dv_ubb.Dv_UbbCode(SQL(5,i),SQL(34,i),1,1)
				End If			
			End If
			TopicBody = Replace(Replace(TopicBody ,"\","\\"),"'","\'")
			'TopicBody = Replace(TopicBody, vbNewLine,"\n")
			SQL(13,i)=Replace(Lcase(SQL(13,i))&"","[isubb]","")
			.Write "document.write (dvbbs_show_topic('"
			.Write SQL(0,i)
			.Write "','"
			.Write Mybbs.BoardID
			.Write "',"
			MyTempStr	= "'"&SQL(2,i)&"','"
			ReplaceStr	= SQL(3,i)&""
			If Not (i=0 And Star=1 And TopicMode=1 ) Then
				ReplaceStr = Replace(ReplaceStr&"","<","&lt;")
				ReplaceStr = Replace(ReplaceStr,">","&gt;")
			End If
			ReplaceStr	=	Replace(Replace(ReplaceStr ,"\","\\"),"'","\'")
			MyTempStr	=	MyTempStr & ReplaceStr
			ReplaceStr	=	SQL(14,i)&""
			ReplaceStr	=	Replace(Replace(ReplaceStr ,"\","\\"),"'","\'")
			SQL(14,i)	=	ReplaceStr
			ReplaceStr	=	SQL(15,i)&""
			ReplaceStr	=	Replace(Replace(ReplaceStr ,"\","\\"),"'","\'")
			SQL(15,i)	=	ReplaceStr
			ReplaceStr	=	SQL(16,i)&""
			ReplaceStr	=	Replace(Replace(ReplaceStr ,"\","\\"),"'","\'")
			SQL(16,i)	=	ReplaceStr
			ReplaceStr	=	SQL(23,i)&""
			ReplaceStr	=	Replace(Replace(ReplaceStr ,"\","\\"),"'","\'")
			ReplaceStr	=	Replace(ReplaceStr&"","<","&lt;")
			ReplaceStr	=	Replace(ReplaceStr,">","&gt;")
			SQL(23,i)	=	ReplaceStr
			ReplaceStr	=	SQL(19,i)&""
			ReplaceStr	=	Replace(Replace(ReplaceStr ,"\","\\"),"'","\'")
			SQL(19,i)	=	ReplaceStr
			MyTempStr	=	MyTempStr & "','"&SQL(13,i)&"','"&SQL(14,i)&"','"&SQL(15,i)&"','"&SQL(16,i)&"','"& SQL(23,i) &"','"&Topic_Ads&"','"&SQL(19,i)&"','"&UserSign&"','"&SQL(30,i)&"','"&TopicBody&"'"
			MyTempStr	= Mybbs.ChkBadWords(MyTempStr)
			MyTempStr	= Replace(Replace(Replace(MyTempStr,chr(13),""),chr(10),""),"$","&#36;")
			.Write MyTempStr
			.Write ",'"
			.Write SQL(4,i)
			.Write "','"
			.Write SQL(6,i)
			.Write "','"
			If Mybbs.GroupSetting(30)="0" Then
				.Write "*.*.*.*"
			Else
				.Write SQL(7,i)
			End If
			.Write  "','"
			.Write AnnounceID
			.Write "',"
			.Write SQL(9,i)
			.Write ","
			.Write SQL(10,i)
			.Write ","
			.Write SQL(11,i)
			.Write ","
			.Write SQL(12,i)
			.Write ",'"
			.Write SQL(18,i)
			.Write "','"
			.Write SQL(20,i)
			.Write "','"
			.Write SQL(21,i)
			.Write "','"
			.Write SQL(22,i)
			.Write "','"
			REM 修正因用户注册时间为空值时出错 2004-5-22 Dv.Yz
			If Not Isdate(SQL(24,i)) Then
				.Write FormatDateTime(Now(),2)
			Else
				.Write FormatDateTime(SQL(24,i),2)
			End If
			.Write "','"
			.Write SQL(25,i)
			.Write "','"
			.Write SQL(26,i)
			.Write "','"
			.Write SQL(27,i)
			.Write "','"
			.Write SQL(28,i)
			.Write "','"
			.Write SQL(29,i)
			.Write "',"
			.Write SQL(31,i)
			.Write ",'"
			.Write SQL(32,i)
			.Write "','"
			.Write SQL(33,i)
			.Write "',"
			.Write SQL(34,i)
			.Write ",'"
			.Write SQL(35,i)
			.Write "','"
			.Write SQL(38,i)
			.Write "',"
			.Write i
			.Write ",'"
			.Write bgcolor
			.Write "','"
			If SQL(37,i)=1 Or DateDiff("s",SQL(35,i),Now())>Cint(Mybbs.Forum_Setting(8))*60 Then
				.Write  "0"
			Else
				.Write  "1"
			End If
			.Write "','"
			.Write SQL(40,i)
			.Write  "'));"
			UbbLists=""
			.Write  "</Script>"
		Next
		SQL=Null
		.Write "<Script Language=JavaScript>"
		MyTempStr = template.html(5)
		MyTempStr = Replace(MyTempStr,"{$width}",Mybbs.mainsetting(0))
		MyTempStr = Replace(MyTempStr,"{$boardid}",Mybbs.BoardID)
		MyTempStr = Replace(MyTempStr,"{$replyid}",ReplyID)
		MyTempStr = Replace(MyTempStr,"{$announceid}",AnnounceID)
		MyTempStr = Replace(MyTempStr,"{$skin}",Skin)
		MyTempStr = Replace(MyTempStr,"{$page}",Page)
		MyTempStr = Replace(MyTempStr,"{$topicnum}",TopicCount)
		MyTempStr = Replace(MyTempStr,"{$boardjump}",Mybbs.BoardJumpList)
		.Write MyTempStr
		.Write  "</Script>"
	End If
	End With
End Function

Function Show_Topic_FastRe()
	Dim TempStr
	With Response
	.Write "<Script Language=JavaScript>"
	.Write "var Board_Setting5='"&Mybbs.Board_Setting(5)&"';"
	.Write "var Board_Setting6='"&Mybbs.Board_Setting(6)&"';"
	.Write "var Board_Setting7='"&Mybbs.Board_Setting(7)&"';"
	.Write "var Board_Setting8='"&Mybbs.Board_Setting(8)&"';"
	.Write "var Board_Setting9='"&Mybbs.Board_Setting(9)&"';"
	.Write "var Board_Setting16='"&Mybbs.Board_Setting(16)&"';"
	.Write "var Board_Setting44='"&Mybbs.Board_Setting(44)&"';"
	.Write "var Forum_Setting3='"&Mybbs.Forum_Setting(3)&"';"
	.Write "var Forum_PostFace='"&Mybbs.Forum_PostFace&"';"
	.Write "var Forum_PostFace=Forum_PostFace.split(""|||"");"
	.Write "</Script>"
	TempStr = template.html(6)
	TempStr = Replace(TempStr,"{$topic}",Topic)
	TempStr = Replace(TempStr,"{$boardid}",Mybbs.BoardID)
	If Mybbs.Board_Setting(4)="0" Then
		'Dim re
		'Set re=new RegExp
		're.IgnoreCase =True
		're.Global=True
		're.Pattern="<(.[^>]*)>"
		'Topic=re.Replace(Topic,"")	
		'Set re=Nothing
		'Topic=server.htmlencode(Topic)
		'Topic=Left(Topic,50)
		'TempStr = Replace(TempStr,"{$getcode}","&nbsp;<B>标题：</B><input name=""topic"" size=20 class=FormClass value=""Re："&Topic&""">")
		TempStr = Replace(TempStr,"{$getcode}","")
	Else
		TempStr = Replace(TempStr,"{$getcode}","&nbsp;<B>验证码：</B>"&Mybbs.GetCode())
	End If
	TempStr = Replace(TempStr,"{$membername}",Mybbs.membername)
	TempStr = Replace(TempStr,"{$followup}",followup)
	TempStr = Replace(TempStr,"{$announceid}",AnnounceID)
	TempStr = Replace(TempStr,"{$star}",Star)
	TempStr = Replace(TempStr,"{$totalusetable}",TotalUseTable)
	TempStr = Replace(TempStr,"{$Forum_Emot}",Replace(Mybbs.Forum_emot&"","|||","<><><>"))
	TempStr = Replace(TempStr,"{$MaxLength}",Clng(Mybbs.Board_Setting(16)))
	Dim Content
	Content=Session(Mybbs.CacheName & "UserID")
	If IsArray(Content) And Mybbs.userID > 0 Then
		TempStr = Replace(TempStr,"{$content}",Server.HTMLEncode(Content(37)))
	Else
		TempStr = Replace(TempStr,"{$content}","")
	End If 
	.Write TempStr
	TempStr = ""
	.Cookies("Mybbs")=""
	End With
End Function

Function Show_Topic_ManageAction()
	Dim TempStr
	TempStr = template.html(7)
	TempStr = Replace(TempStr,"{$width}",Mybbs.mainsetting(0))
	TempStr = Replace(TempStr,"{$boardid}",Mybbs.BoardID)
	TempStr = Replace(TempStr,"{$announceid}",AnnounceID)
	TempStr = Replace(TempStr,"{$replyid}",ReplyID)
	If IsTop > 0 Then
		TempStr = Replace(TempStr,"{$topstr}",template.Strings(10))
	Else
		TempStr = Replace(TempStr,"{$topstr}",template.Strings(11))
	End If
	Response.Write TempStr
	TempStr = ""
End Function

Function Show_Topic_Vote()
	Dim TempStr,Rs,Trs
	Set Rs=Mybbs.Execute("Select * From Dv_Vote Where VoteID="&PollID)
	If Not (Rs.Eof And Rs.Bof) Then
		Response.Write "<Script Language=JavaScript>"
		Response.Write "var vote='"&Rs("vote")&"';"
		Response.Write "var votenum='"&Rs("votenum")&"';"
		Response.Write "var votetype='"&Rs("votetype")&"';"
		Response.Write "var voters='"&Rs("voters")&"';"
		Response.Write "</Script>"
		TempStr = template.html(8)
		TempStr = Replace(TempStr,"{$topic}",Topic)
		TempStr = Replace(TempStr,"{$announceid}",AnnounceID)
		TempStr = Replace(TempStr,"{$votetype}",Rs("votetype"))
		If Mybbs.UserID=0 Or datediff("d",rs("timeout"),Now())>0 Or locktopic=1 Then
			TempStr = Replace(TempStr,"{$uservoteinfo}",Split(template.html(9),"||")(0))
		Else
			Set Trs=Mybbs.Execute("Select Count(*) From Dv_voteuser Where voteid="&PollID&" And userid="&Mybbs.userid)
			If Trs(0)=0 Then 
				TempStr = Replace(TempStr,"{$uservoteinfo}",Split(template.html(9),"||")(1))
			Else
				TempStr = Replace(TempStr,"{$uservoteinfo}",Split(template.html(9),"||")(2))
			End If
			Set Trs=Nothing 
		End  If
		TempStr = Replace(TempStr,"{$timeout}",Rs("timeout"))
		TempStr = Replace(TempStr,"{$boardid}",Mybbs.BoardID)
		TempStr = Replace(TempStr,"{$voteid}",PollID)
		TempStr = Replace(TempStr,"{$uarticle}",Rs("UArticle")&"")
		TempStr = Replace(TempStr,"{$uep}",Rs("UEP")&"")
		TempStr = Replace(TempStr,"{$ucp}",Rs("UCP")&"")
		TempStr = Replace(TempStr,"{$upower}",Rs("UPower")&"")
		TempStr = Replace(TempStr,"{$umoney}",Rs("UWealth")&"")
		'Response.Write TempStr
		Show_Topic_Vote = TempStr
		TempStr = ""
	End If
	Set Rs=Nothing
End Function

Function SimJsReplace(str)
	If IsNull(str) Or str="" Then Exit Function
	str=Replace(str,"\","\\")
	str=Replace(str,"'","\'")
	str=Replace(str,"$","&#36;")
	SimJsReplace=str
End Function
Function Dvbbs_TopicMode(str,tmode)
	Select Case tmode
	Case "1"
		Dvbbs_TopicMode=str
	Case "2"
		Dvbbs_TopicMode="<font color=red>"&Mybbs.Htmlencode(str)&"</font>"
	Case "3"
		Dvbbs_TopicMode="<font color=blue>"&Mybbs.Htmlencode(str)&"</font>"
	Case "4"
		Dvbbs_TopicMode="<font color=green>"&Mybbs.Htmlencode(str)&"</font>"
	Case Else
		Dvbbs_TopicMode=Mybbs.HtmlEncode(str)
	End Select
End Function
Sub Showtree()
	template.html(10) = Replace(template.html(10),"{$boardid}",Mybbs.BoardID)
	template.html(10) = Replace(template.html(10),"{$replyid}",ReplyID)
	template.html(10) = Replace(template.html(10),"{$announceid}",AnnounceID)
	template.html(10) = Replace(template.html(10),"{$openid}",followup)
	Response.Write template.html(10)
End Sub
Function AnnounceIDlist()
	Dim Rs,SQL,i,starcount
	starcount=(Star-1)*Mybbs.Board_Setting(27)
	SQL="Select Announceid From "&TotalUseTable&" Where BoardID="&Mybbs.BoardID&" And RootID="&Announceid&" Order By AnnounceID"
	Set Rs=Mybbs.Execute(SQL)
	If Not Rs.Eof Then
		Rs.Move Starcount
		REM 修正最后页面出错信息 2004-5-22 Dv.Yz
		If Rs.Eof Then
			Mybbs.AddErrcode(33)
			Mybbs.Showerr()
		End If
		AnnounceIDlist = Rs(0)
		Rs.Movenext
		For i = 1 To Mybbs.Board_Setting(27)
			If Rs.Eof Then Exit For
			AnnounceIDlist = AnnounceIDlist & "," & Rs(0)
			Rs.Movenext
		Next
	Else
		Mybbs.AddErrcode(32)
		Mybbs.Showerr()
	End If 
	Set Rs=Nothing 
End Function 
%>