www.gusucode.com > CC校友录贴吧 CCBar源码程序asp编程 > admin/admin_article_manage.asp

    <%
'===================================================================
'= ASP FILENAME	: /admin/admin_article_manage.asp
'= CREATED TIME : 2006-5-8
'= LAST MODIFIED: 2006-5-8
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 文章管理
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/admin/include_admin_action_view.asp" -->
<!-- #include file = "./admin_inc.asp" -->
<!-- #include file = "../inc/logic/logic_content.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "admin/admin_article_manage.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "文章管理"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ShowArticleCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_objRS			'== 列表记录集
Dim TAG_strPageNav		'== 翻页导航
Dim TAG_strSort			'== 所属信息分类名
Dim TAG_intSortId		'== 所属信息分类id

'== 请求校验与过滤
Call ActionViewFilterAdmin(CONST_PAGE_FILE,CONST_ACTION_FUNC)


'== 页面析构
Call ActionOver()
%>


<%
'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "../template_a/page_admin_article_manage.html.asp" -->
<%
End Function
'===================================================================
'= Function	   : ShowArticleCtl()
'= Time		   : Created At 2006-5-8
'= Input       : None
'= Description : 文章管理
'===================================================================
Function ShowArticleCtl()

	Dim strFileName 
	Dim intMaxPerPage
	Dim intCurPage,intTotalPut
	Dim intSortId

	intMaxPerPage = GBL_intMaxPerPage
	TAG_intPerPage = GBL_intMaxPerPage

	'== 获取ID参数
	If Not GetPostIdValue("intSortId","信息分类",intSortId) Then Exit Function
	TAG_intSortId = intSortId

	'== 取得所属信息分类
	If Not GetSortLogic(intSortId) Then Exit Function
	TAG_strSort = GBL_objPubDB.objPubRS("SORT_NAME")

	strFileName = "admin_article_manage.asp?intSortId=" & intSortId
	
	'== 取文章记录集
	If Not GetArticlesLogic(" AND ARTICLE_SORT_ID=" & intSortId) Then Exit Function

	If Not ResultExecute(GBL_objPubDB.intRSNum,"文章","ES_DB_NO") Then

		Set TAG_objRS = GBL_objPubDB.objPubRS
	
		intTotalPut = GBL_objPubDB.intRSNum

		intCurPage = GetCurPage(intMaxPerPage,intTotalPut)
		
		If intCurPage > 1 Then		
			If (intCurPage - 1) * intMaxPerPage < intTotalPut Then
				GBL_objPubDB.objPubRS.Move  (intCurPage - 1) * intMaxPerPage
				Dim BookMark
				BookMark = GBL_objPubDB.objPubRS.BookMark	
			End If
		End If
		
		TAG_strPageNav = ShowPageNav(intTotalPut,intMaxPerPage,intCurPage,strFileName)

	End If

End Function
%>