www.gusucode.com > CC校友录贴吧 CCBar源码程序asp编程 > dialog/dialog_collection_save.asp

    <%
'===================================================================
'= ASP FILENAME	: /dialog/dialog_collection_save.asp
'= CREATED TIME : 2006-5-5
'= LAST MODIFIED: 2006-5-5
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 加为收藏
'= Change Log:
'===================================================================
%>
<!-- #include file = "../inc/customer/include_customer_action_execute.asp" -->
<!-- #include file = "./dialog_inc.asp" -->
<!-- #include file = "../inc/logic/logic_collection.asp" -->
<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "dialog/dialog_collection_save.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "加为收藏"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "FormSaveAddCollectionCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 在模板中引用的标签变量
Dim TAG_strVerifyCode
Dim TAG_strClew

'== 页面构造
Call ActionBuild()

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()

%>
<%
'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_dialog.html.asp" --> 
<%
End Function

'=====================================================================
'= Function    : FormSaveAddCollectionCtl()
'= Time        : Created At 2006-5-6
'= Input       : 
'= Description : 加为收藏
'=====================================================================
Function FormSaveAddCollectionCtl()
	Dim strClew

	'== 服务器端数据校验
	If Not ServerDataCheck(arrCollectionAddDataChk) Then
		TAG_strClew = "操作失败，" & GBL_objException.getErrInfo() & "&nbsp;&nbsp;<span onclick='javascript:window.close();' style='cursor:hand'><u>[关闭窗口]</u></span>"
		GBL_objException.errReset()
		Exit Function
	End If

	'== 数据获取
	Call CnvFormData(strCollectionAddFormName,GBL_objFormData)

	Select Case GBL_objFormData.Item("Type")
		Case	0	:
				strClew = "您已经添加此用户为我的好友"
		Case	1	:
				strClew = "您已经添加此帖子为我的收藏"
		Case	2	:
				strClew = "您已经添加此相片为我的收藏"
	End Select

	'== 添加
	If Not SaveCollectionLogic(GBL_intUserId,GBL_objFormData) Then
		strClew = GBL_objException.getErrInfo()
		TAG_strClew = "操作失败，" & strClew & "<span onclick='javascript:window.close();' style='cursor:hand'><u>[关闭窗口]</u></span>"
		GBL_objException.errReset()
		Exit Function
	Else
		TAG_strClew = "操作成功，" & strClew & "&nbsp;&nbsp;<span onclick='javascript:window.close();' style='cursor:hand'><u>[关闭窗口]</u></span>"
	End If
 
End Function
%>