www.gusucode.com > CC校友录贴吧 CCBar源码程序asp编程 > forum/forum_add_topics.asp

    <%
'===================================================================
'= ASP FILENAME	: /forum/forum_add_topics.asp
'= CREATED TIME : 2006-5-4
'= LAST MODIFIED: 2006-5-4
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 发表贴吧新贴
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./forum_func.asp" -->
<!-- #include file = "./forum_inc.asp" -->
<!-- #include file = "../inc/inc_ubb.asp" -->
<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "forum/forum_add_topics.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "发表贴吧新贴"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "FormAddTopicsCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_strVerifyCode	'== 表单校验
Dim TAG_objDicUnit		'== 单列记录

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)


'== 页面析构
Call ActionOver()
%>


<%
'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_forum_add_topics_form.html.asp" --> 
<%
End Function

'===================================================================
'= Sub         : FormAddTopicsCtl()
'= Time		   : Created At Jan,18,2004
'= Input       : None
'= Description : 发表贴吧新贴
'===================================================================
Sub FormAddTopicsCtl()

	Dim clsForm			'== Class of form
	Dim strHtmlCode
	Dim strActFlag
	Dim strAddInfo,intErrId
	Dim GetRSId
	Dim strTilte,strContent,strFace,strTitle,ForumId

	strTitle = ""
	strContent = ""
	strFace = "14.gif"
	strContent = ""		'== for quote

	strActFlag = Trim(Request.QueryString("pstActFlag"))
	If strActFlag <> "" And strActFlag <> "FORUM_EDIT_MODE" Then
		Call ResultExecute(E_USER_PUB,"贴子编辑模式不正确","ES_ERR")
		Exit Sub
	End If

	'== 贴吧导航条
	If strActFlag = "FORUM_EDIT_MODE" Then
		Call ShowAddTopicsForumMenu("编辑帖子")
	Else
		Call ShowAddTopicsForumMenu("发新贴")
	End If

	ForumId = Trim(Request.QueryString("ForumId"))
	strAddInfo = "贴吧栏目"
	intErrId = DataCheck("DT_ID",ForumId,strAddInfo,"ES_ERR")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	Call CheckMasterForum(ForumId)

	'== edit mode 
	If strActFlag = "FORUM_EDIT_MODE" Then

		GetRSId = Trim(Request.QueryString("TopicsId"))
		strAddInfo = "该要编辑的帖子"
		intErrId = DataCheck("DT_ID",GetRSId,strAddInfo,"")
		Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

		GBL_objPubDB.Clear()
		GBL_objPubDB.TableName = "CLASS_TOPICS"
		GBL_objPubDB.SQLType = "SELECT"
		If GBL_strUserAuthen = 1 Or GetMaster(ForumId) Then
			GBL_objPubDB.Where = "TOPICS_ID=" & GetRSId 
		Else
			GBL_objPubDB.Where = "TOPICS_ID=" & GetRSId & " AND TOPICS_OWNER_ID=" & GBL_intUserId
		End If
		GBL_objPubDB.AddField "TOPICS_TITLE,TOPICS_CONTENT,TOPICS_SUBJECT,TOPICS_FACE",""
		GBL_objPubDB.SQLRSExecute()
		Call ResultExecute(GBL_objPubDB.intErrNum,"get edit topics content","ES_ERR")
		If GBL_objPubDB.intRSNum = 0 Then
			Call ResultExecute(E_USER_PUB,"该要编辑帖子不存在或已删除","ES_ERR")
			Exit Sub
		End If
		strTitle = GBL_objPubDB.objPubRS("TOPICS_TITLE")
		strContent = GBL_objPubDB.objPubRS("TOPICS_CONTENT")
		strFace = GBL_objPubDB.objPubRS("TOPICS_FACE")
		Dim intSubject : intSubject = GBL_objPubDB.objPubRS("TOPICS_SUBJECT")

	End If

	Set clsForm = New classForm
	If strActFlag = "FORUM_EDIT_MODE" Then
		clsForm.Action = "./forum_add_save.asp?action=FormSaveAddTopics&pstActFlag=FORUM_EDIT_MODE&TopicsId=" & GetRSId
	Else
		clsForm.Action = "./forum_add_save.asp?action=FormSaveAddTopics"
	End If

	clsForm.Id = "vbform"
	clsForm.Name = "vbform"
	clsForm.OnSubmit = "return CheckFormAddTopics(this)"
	'clsForm.DataChkArr = arrAddBoardDataChk
	clsForm.ColumnScale = "25%"
	clsForm.MakeForm()
	clsForm.MakeTableSet "0","5","1","center","540","TBone"

	clsForm.AddTrByStyle "TBHead"
	If strActFlag = "FORUM_EDIT_MODE" Then
		clsForm.AddTitle "<b>修 改 贴 子</b>"
	Else
		clsForm.AddTitle "<b>发 表 新 贴 子</b>"
	End If

	Dim strTmp
	GBL_cssFormTdOne = "TBBG9"
	GBL_cssFormTdTwo = "TBBG1"
	GBL_cssFormTr = ""

	clsForm.AddTrByStyle  GBL_cssFormTr

	strTmp = "&nbsp;<br/><select onchange='document.vbform.iptTitle.value=this.value+document.vbform.iptTitle.value;document.vbform.iptTitle.focus();'><OPTION selected value=''>话题</option> <OPTION value=[原创]>[原创] </option> <OPTION value=[转帖]>[转帖] <OPTION value=[灌水]>[灌水]</option> <OPTION value=[讨论]>[讨论] <OPTION value=[求助]>[求助] <OPTION value=[推荐]>[推荐] </option> <OPTION value=[公告]>[公告]<OPTION value=[注意]>[注意] </option> <OPTION value=[贴图]>[贴图]<OPTION value=[建议]>[建议] <OPTION value=[下载]>[下载]</option> <OPTION value=[分享]>[分享]</option></select>"

	clsForm.AddTdByStyle "*帖子主题" & strTmp,GBL_cssFormTdOne & " align=absmiddle ",GBL_cssFormTdTwo
	clsForm.AddText "iptTitle class='fminpt' ","100","65"
	clsForm.AddValue strTitle

	'== get now smile
	Call ForumFace(clsForm,strFace)

	clsForm.AddTrByStyle GBL_cssFormTr
	clsForm.AddTdByStyle "UBB标签",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine GetUbb()

	clsForm.AddTrByStyle GBL_cssFormTr
	clsForm.AddTdByStyle "*帖子内容",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddTextrea "txtContent class=fmtxtra ","65","20"
	clsForm.AddValue FilterHtml(strContent)

	'clsForm.AddTrByStyle GBL_cssFormTr
	'clsForm.AddTdByStyle "本版专题",GBL_cssFormTdOne,GBL_cssFormTdTwo
	'== subject
	'If Not IsEmpty(DEF_FormSubject(ForumId)) Then
	'	If IsArray(DEF_FormSubject(ForumId)) Then
	'		clsForm.AddSelect "selForumSubject",""
	'		clsForm.AddOption 0,"一般贴",intSubject
	'		arrNowSub = DEF_FormSubject(ForumId)
	'		For n = Lbound(arrNowSub) To Ubound(arrNowSub)
	'			Response.Write arrNowSub(n)
	'			clsForm.AddOption n+1,arrNowSub(n),intSubject
	'		Next		
	'	Else
	'		clsForm.AddLine "没有专题可以指定"
	'	End If
	'Else
	'	clsForm.AddLine "没有专题可以指定"
	'End If

	clsForm.AddTrByStyle GBL_cssFormTr
	clsForm.AddTdByStyle "*插入表情",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine ShowSmileOut(11)


	clsForm.AddTrByStyle GBL_cssFormTr
	clsForm.AddTdByStyle "帖子提交",GBL_cssFormTdOne,GBL_cssFormTdTwo
	strHtmlCode = "<input type=hidden name='hidForumId' id='hidForumId' value=" & ForumId & ">"
	clsForm.AddLine "Alt+S或Ctrl+Enter快速提交" & strHtmlCode

	clsForm.AddTrByStyle  "TBBG9"
	clsForm.AddSubTdByStyle " align=center "
	clsForm.AddSub "subAddTopics","提 交","submit class='fmbtn' "
	clsForm.AddSub "rstAddTopics","重 写","submit class='fmbtn' "

	clsForm.OutPutForm()
	Set clsForm = Nothing

End Sub


'====================================================================
'= Function    : ForumFace(strInFace)
'= Time		   : Created At Feb,29,2004
'= Input       : objForm   : form object
'=				 strInFace : now smile 
'= Description : face show fo forum
'====================================================================
Function ForumFace(ByRef objForm,strInFace)

	objForm.AddTrByStyle "" 
	objForm.AddTdByStyle "发帖心情","TBBG9","TBBG1"
	objForm.AddRadio "rdoFace","14.gif","<img src='" & GBL_strHomeURL & "images/smile/14.gif' title='微笑' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","12.gif","<img src='" & GBL_strHomeURL & "images/smile/12.gif' title='高兴' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","5.gif","<img src='" & GBL_strHomeURL & "images/smile/5.gif' title='悲伤' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","32.gif","<img src='" & GBL_strHomeURL & "images/smile/32.gif' title='疑惑' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","76.gif","<img src='" & GBL_strHomeURL & "images/smile/76.gif' title='强' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","23.gif","<img src='" & GBL_strHomeURL & "images/smile/23.gif' title='傲慢' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","25.gif","<img src='" & GBL_strHomeURL & "images/smile/25.gif' title='困' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","6.gif","<img src='" & GBL_strHomeURL & "images/smile/6.gif' title='害羞' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","20.gif","<img src='" & GBL_strHomeURL & "images/smile/20.gif' title='偷笑' align='absmiddle' valign='middle'>",strInFace

End Function


%>