www.gusucode.com > CC校友录贴吧 CCBar源码程序asp编程 > forum/forum_reply_inc.asp

    <%
'===================================================================
'= ASP FILENAME	: /forum/forum_reply_inc.asp
'= CREATED TIME : SEP,12,2004
'= LAST MODIFIED: SEP,12,2004
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : reply forum
'= Change Log:
'===================================================================
%>

<%
'===================================================================
'= Sub         : FormAddReply()
'= Time		   : Created At Jan,31,2004
'= Input       : None
'= Description : Add new forum reply
'===================================================================
Sub FormAddReply()

	Dim clsForm			'== Class of form
	Dim strHtmlCode
	Dim strActFlag
	Dim intErrId
	Dim strAddInfo
	Dim strTitle		'== the topic title
	Dim GetRSId,GetRSId1
	Dim strContent,strFace,ReplyId

	strContent = ""
	strFace = "14.gif"
	strTitle = ""

	strActFlag = Trim(Request.QueryString("pstActFlag"))
	If strActFlag <> "" And strActFlag <> "FORUM_EDIT_MODE" Then
		Call ResultExecute(E_USER_PUB,"贴子编辑模式不正确","ES_ERR")
		Exit Sub
	End If

	Dim ForumId : ForumId = Trim(Request.QueryString("ForumId"))
	strAddInfo = "贴吧栏目"
	intErrId = DataCheck("DT_ID",ForumId,strAddInfo,"ES_ERR")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	'== 是否允许回复
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT FORUM_READ_ONLY FROM CLASS_FORUM WHERE FORUM_ID=" & ForumId
	GBL_objPubDB.SQLRSExecute()
	If GBL_objPubDB.objPubRS("FORUM_READ_ONLY") = 1 Then
		If CONST_PAGE_FILE	<> "forum/forum_show.asp" Then
			Call GBL_objException.catchErr(E_USER_PUB,"该板块的帖子不允许回复")
			Exit Sub
		Else
			Response.Write "该板块的帖子不允许回复"
			Exit Sub
		End If
	End If

	'== 贴吧导航条
	If strActFlag = "FORUM_EDIT_MODE" Then
		Call ShowAddReplyForumMenu("编辑回复")
	Else
		Call ShowAddReplyForumMenu("发表回复")
	End If

	'== 是否允许回复
	'GBL_objPubDB.Clear()
	'GBL_objPubDB.AllSQL = "SELECT FORUM_READ_ONLY FROM CLASS_FORUM WHERE FORUM_ID=" & ForumId
	'GBL_objPubDB.SQLRSExecute()
	'If GBL_objPubDB.objPubRS("FORUM_READ_ONLY") = 1 Then
	'	If CONST_PAGE_FILE	<> "forum/forum_show.asp" Then
	'		Call GBL_objException.catchErr(E_USER_PUB,"该板块的帖子不允许回复")
	'		Exit Sub
	'	End If
	'End If

	'== check title
	'strTitle = Trim(Request.QueryString("pstTitle"))
	Call CheckMasterForum(ForumId)

	'== edit mode 
	If strActFlag = "FORUM_EDIT_MODE" Then

		GetRSId1 = Trim(Request.QueryString("ReplyId"))
		strAddInfo = "该要编辑的帖子回复"
		intErrId = DataCheck("DT_ID",GetRSId1,strAddInfo,"")
		Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

		GBL_objPubDB.Clear()
		GBL_objPubDB.TableName = "CLASS_REPLY"
		GBL_objPubDB.SQLType = "SELECT"
		If GBL_strUserAuthen = 1 Or GetMaster(ForumId) Then
			GBL_objPubDB.Where = "REPLY_ID=" & GetRSId1
		Else
			GBL_objPubDB.Where = "REPLY_ID=" & GetRSId1 & " AND REPLY_OWNER_ID=" & GBL_intUserId
		End If
		GBL_objPubDB.AddField "REPLY_CONTENT,REPLY_FACE,REPLY_TITLE",""
		GBL_objPubDB.SQLRSExecute()
		Call ResultExecute(GBL_objPubDB.intErrNum,"get edit reply content","ES_ERR")
		If GBL_objPubDB.intRSNum = 0 Then
			Call ResultExecute(E_USER_PUB,"该要编辑帖子不存在或已删除","ES_ERR")
			Exit Sub
		End If
		strContent = GBL_objPubDB.objPubRS("REPLY_CONTENT")
		strFace = GBL_objPubDB.objPubRS("REPLY_FACE")
		strTitle = GBL_objPubDB.objPubRS("REPLY_TITLE")

	End If

	'== quote reply
	If Trim(Request.QueryString("ACT_MODE")) = "ACT_REPLY_QUOTE" Then
	
		ReplyId = Trim(Request.QueryString("ReplyId"))
		strAddInfo = "引用贴"
		intErrId = DataCheck("DT_ID",ReplyId,strAddInfo,"ES_ERR")
		Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

		GBL_objPubDB.Clear()
		GBL_objPubDB.AllSQL = "SELECT REPLY_CONTENT,USER_REALNAME FROM CLASS_REPLY,CLASS_USER WHERE USER_ID=REPLY_OWNER_ID AND REPLY_ID=" & ReplyId
		GBL_objPubDB.SQLRSExecute()
		Call ResultExecute(GBL_objPubDB.intErrNum,"quote reply","ES_ERR")

		If GBL_objPubDB.intRSNum > 0 Then
			strContent = "[QUOTE]引用" & GBL_objPubDB.objPubRS("USER_REALNAME") & "发表的内容:<br>" & GBL_objPubDB.objPubRS("REPLY_CONTENT") & "[/QUOTE]"
		End If
		
	End If

	'== check id
	GetRSId = Trim(Request.QueryString("TopicsId"))
	strAddInfo = "该需回复帖子"
	intErrId = DataCheck("DT_ID",GetRSId,strAddInfo,"")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	'== get title
	Dim strInTitle
	If CONST_PAGE_FILE = "forum/forum_show.asp" Then
		strTitle = strInTitle
	Else
		If strActFlag <> "FORUM_EDIT_MODE" Then
			GBL_objPubDB.Clear()
			GBL_objPubDB.AllSQL = "SELECT TOPICS_TITLE  FROM CLASS_TOPICS WHERE TOPICS_ID=" & GetRSId
			GBL_objPubDB.SQLRSExecute()
			Call ResultExecute(GBL_objPubDB.intErrNum,"get add reply title","ES_ERR")
			If GBL_objPubDB.intRSNum = 0 Then
				Call ResultExecute(E_USER_PUB,"该要回复的帖子不存在或已删除","ES_ERR")
				Exit Sub
			End If
			strTitle = GBL_objPubDB.objPubRS("TOPICS_TITLE")
		End If
	End If

	'== check topics status
	If CONST_PAGE_FILE = "forum/forum_show.asp" Then
	Else
		GBL_objPubDB.Clear()
		GBL_objPubDB.AllSQL = "SELECT TOPICS_REPLY_FORBID FROM CLASS_TOPICS WHERE TOPICS_ID=" & GetRSId
		GBL_objPubDB.SQLRSExecute()
		Call ResultExecute(GBL_objPubDB.intErrNum,"get before reply topics ","ES_ERR")
		If GBL_objPubDB.intRSNum <= 0 Then
			Call ResultExecute(E_USER_PUB,"该帖子不存在","ES_ERR")
			Exit Sub
		ElseIf GBL_objPubDB.objPubRS("TOPICS_REPLY_FORBID") = 1 Then
			Call ResultExecute(E_USER_PUB,"该帖子已被设置为禁止回复","ES_ERR")
			Exit Sub 
		End If
	End If

	Set clsForm = New classFormOld
	If strActFlag = "FORUM_EDIT_MODE" Then
		clsForm.Action = "forum_add_save.asp?action=FormSaveAddReply&TopicsId=" & GetRSId & "&pstActFlag=FORUM_EDIT_MODE&ReplyId=" & GetRSId1
	Else
		clsForm.Action = "forum_add_save.asp?action=FormSaveAddReply&TopicsId=" & GetRSId
	End If
	clsForm.Id = "vbform"
	clsForm.Name = "vbform"
	clsForm.OnSubmit = "return CheckFormAddReply(this)"
	clsForm.ColumnScale = "20%"
	clsForm.MakeForm()
	clsForm.MakeTable "0","3","1","center","540","TBone"

	clsForm.AddTr "TBHead"
	If strActFlag = "FORUM_EDIT_MODE" Then
		clsForm.AddTitle "<b>修改回复帖子</b>","TBHead style='text-align:left;'"
	Else
		clsForm.AddTitle "<b>回复帖子</b>","TBHead style='text-align:left;'"
	End If

	GBL_cssFormTr = ""
	GBL_cssFormTdOne = "TBBG1"
	GBL_cssFormTdTwo = "TBBG9"
	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "回贴主题",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddText "iptReTitle class=fminpt ","100","65"
	If strActFlag <> "FORUM_EDIT_MODE" Then
		strTitle = "Re:" & strTitle
	End If
	clsForm.AddValue strTitle

	'== get now smile
	Call ForumFace(clsForm,strFace)

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "UBB标签",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine GetUbb()

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "*回复内容",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddTextrea "txtContent class=fmtxtra ","65","15"
	clsForm.AddValue FilterHtml(strContent)

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "*插入表情",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine ShowSmileOut(14)

	'clsForm.AddTr GBL_cssFormTr
	'clsForm.AddTd "*回复选项",GBL_cssFormTdOne,GBL_cssFormTdTwo
	'clsForm.AddChkBox "chkSign",0,"使用个性签名",0

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "帖子提交",GBL_cssFormTdOne,GBL_cssFormTdTwo
	strHtmlCode = "<input type=hidden name='hidForumId' id='hidForumId' value=" & ForumId & ">"
	clsForm.AddLine "Alt+S或Ctrl+Enter快速提交" & strHtmlCode

	clsForm.AddTr "TBBG9"
	clsForm.AddSubTd " align=center "
	clsForm.AddSub "subAddReply","提 交","submit class='fmbtn' "
	clsForm.AddSub "rstAddReply","重 写","reset class='fmbtn' "
	
	clsForm.OutPutForm()
	Set clsForm = Nothing

End Sub
'============== End of Function FormAddReply() ======================
'====================================================================
'= Function    : ForumFace(strInFace)
'= Time		   : Created At Feb,29,2004
'= Input       : objForm   : form object
'=				 strInFace : now smile 

'= Called by   : 
'= Calls       : 
'= Description : face show fo forum
'====================================================================
Function ForumFace(ByRef objForm,strInFace)

	objForm.AddTr GBL_cssFormTr
	objForm.AddTd "*发帖心情",GBL_cssFormTdOne,GBL_cssFormTdTwo
	objForm.AddRadio "rdoFace","14.gif","<img src='" & GBL_strHomeURL & "images/smile/14.gif' title='微笑' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","12.gif","<img src='" & GBL_strHomeURL & "images/smile/12.gif' title='高兴' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","5.gif","<img src='" & GBL_strHomeURL & "images/smile/5.gif' title='悲伤' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","32.gif","<img src='" & GBL_strHomeURL & "images/smile/32.gif' title='疑惑' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","76.gif","<img src='" & GBL_strHomeURL & "images/smile/76.gif' title='强' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","23.gif","<img src='" & GBL_strHomeURL & "images/smile/23.gif' title='傲慢' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","25.gif","<img src='" & GBL_strHomeURL & "images/smile/25.gif' title='困' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","6.gif","<img src='" & GBL_strHomeURL & "images/smile/6.gif' title='害羞' align='absmiddle' valign='middle'>",strInFace
	objForm.AddRadio "rdoFace","20.gif","<img src='" & GBL_strHomeURL & "images/smile/20.gif' title='偷笑' align='absmiddle' valign='middle'>",strInFace

End Function

'====================================================================
'= Function    : ForumIcoShow()
'= Called by   : 
'= Calls       : 
'= Description : ico
'====================================================================
Function ForumIcoShow()
%>
	<table width=100% >
		<tr width=100%>
			<td width=100% align=center valign=bottom>贴吧图例：
			<img src="<%=GBL_strHomeURL%>images/Ico/User_info.gif"  align=absmiddle valign='middle'>发贴者信息&nbsp;
			<img src="<%=GBL_strHomeURL%>images/Ico/forum_quote.gif" align=absmiddle valign='middle'>引用留言&nbsp;
			<img src="<%=GBL_strHomeURL%>images/Ico/forum_del.gif" align=absmiddle valign='middle'>删除&nbsp;
			<img src="<%=GBL_strHomeURL%>images/Ico/forum_edit.gif" align=absmiddle valign='middle'>编辑&nbsp;
			<img src="<%=GBL_strHomeURL%>images/Ico/User_sms.gif" align=absmiddle valign='middle'>发站内短信&nbsp;
			</td>
		</tr>
	</table>
<%
End Function
%>