www.gusucode.com > CC校友录贴吧 CCBar源码程序asp编程 > inc/logic/logic_config.asp

    <%
''===================================================================
'= ASP FILENAME	: /inc/logic/logic_config.asp
'= CREATED TIME : 2006-5-1
'= LAST MODIFIED: 2006-5-1
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 网站信息设置业务逻辑
'= Change Log:
'==================================================================='
%>

<%
Const ABOUT_TYPE_INTRO = "ABOUT_INTRO"
Const ABOUT_TYPE_DEV = "ABOUT_DEV"
Const ABOUT_TYPE_ORG = "ABOUT_ORG"
Const ABOUT_TYPE_CONTACT = "ABOUT_CONTACT"
''===================================================================
'= Function    : GetConfigLogic()
'= Time		   : Created At 2006-5-5
'= Return      : boolean
'= Description : 取网站信息记录
'==================================================================='
Function GetConfigLogic()
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT CONFIG_ID,CONFIG_LAST_TIME,CONFIG_COPY_RIGHT,CONFIG_CONTACT,CONFIG_EMAIL,CONFIG_CREATER,CONFIG_CREATE_TIME,CONFIG_LAST_ADMIN_ID,CONFIG_SITE_NAME,CONFIG_RECORD,CONFIG_SITE_URL,CONFIG_HOME_URL FROM CLASS_CONFIG "
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetConfigLogic = False
		Exit Function
	End If
	GetConfigLogic = True
End Function

''===================================================================
'= Function    : GetForumConfigLogic()
'= Time		   : Created At 2006-5-5
'= Return      : boolean
'= Description : 取贴吧设置
'==================================================================='
Function GetForumConfigLogic()
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT FORUM_ID,FORUM_NAME,FORUM_ICO,FORUM_DES,FORUM_MASTER,FORUM_MASTER_NAME FROM CLASS_FORUM"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetForumConfigLogic = False
		Exit Function
	End If
	GetForumConfigLogic = True
End Function

''===================================================================
'= Function    : GetSetupLogic()
'= Time		   : Created At 2006-5-5
'= Return      : boolean
'= Description : 取参数设置记录
'==================================================================='
Function GetSetupLogic()
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT SETUP_LAST_ADMIN_ID,SETUP_LAST_TIME,SETUP_ALBUM_SIZE,SETUP_LISTID,SETUP_CCID,SETUP_OPEN_LIST,SETUP_CCBUTTON,SETUP_ADMIN_PER_PAGE,SETUP_USER_PER_PAGE,SETUP_USER_REG,SETUP_USER_REG_QUES FROM CLASS_SETUP"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetSetupLogic = False
		Exit Function
	End If
	GetSetupLogic = True
End Function

''===================================================================
'= Function    : GetForumCatesLogic()
'= Time		   : Created At 2006-5-5
'= Return      : boolean
'= Description : 取贴吧分类记录
'==================================================================='
Function GetForumCatesLogic()
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT CATE_ID,CATE_NAME FROM CLASS_CATE ORDER BY CATE_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetForumCatesLogic = False
		Exit Function
	End If
	GetForumCatesLogic = True
End Function

''===================================================================
'= Function    : GetLinksLogic()
'= Time		   : Created At 2006-7-6
'= Return      : boolean
'= Description : 取link
'==================================================================='
Function GetLinksLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT * FROM CLASS_LINK WHERE 1=1 " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetLinksLogic = False
		Exit Function
	End If
	GetLinksLogic = True
End Function

''===================================================================
'= Function    : GetAboutLogic()
'= Time		   : Created At 2006-7-6
'= Return      : boolean
'= Description : 取校友录介绍
'==================================================================='
Function GetAboutLogic()
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT ABOUT_INTRO,ABOUT_BOARD,ABOUT_REG,ABOUT_DEV,ABOUT_HELP,ABOUT_ORG,ABOUT_CONTACT FROM CLASS_ABOUT "
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetAboutLogic = False
		Exit Function
	End If
	GetAboutLogic = True
End Function

''===================================================================
'= Function    : SaveLinkLogic()
'= Time		   : Created At 2006-7-6
'= Return      : boolean
'= Description : save校友录介绍
'==================================================================='
Function SaveLinkLogic(intLinkId,objFormData)
	GBL_objPubDB.Clear()
	GBL_objPubDB.SQLType = "INSERT"
	GBL_objPubDB.TableName = "CLASS_LINK"
	GBL_objPubDB.AddField "LINK_NAME",objFormData.Item("Name")
	GBL_objPubDB.AddField "LINK_DESC",objFormData.Item("Desc")
	GBL_objPubDB.AddField "LINK_URL",objFormData.Item("LinkUrl")
	GBL_objPubDB.AddField "LINK_LOGO_IMG",objFormData.Item("LogoLink")
	GBL_objPubDB.AddField "LINK_LOGO_SET",objFormData.Item("LogoSet")
	If Not GBL_objPubDB.SQLRSExecute() Then
		SaveLinkLogic = False
		Exit Function
	End If

	If Not LoadParaLogic() Then Exit Function

	SaveLinkLogic = True
End Function

''===================================================================
'= Function    : RemoveLinksLogic()
'= Time		   : Created At 2006-7-6
'= Return      : boolean
'= Description : 删除友情链接
'==================================================================='
Function RemoveLinksLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "DELETE FROM CLASS_LINK WHERE 1=1 " & strWhere
	If Not GBL_objPubDB.SQLExecute() Then
		RemoveLinksLogic = False
		Exit Function
	End If
	RemoveLinksLogic = True
End Function

''===================================================================
'= Function    : MakeHtmlLinkLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : strWhere 符合条件
'= Input	   : strFile  文件地址
'= Return      : boolean
'= Description : 生成友情链接的link html文件
'==================================================================='
Function MakeHtmlLinkLogic(strWhere,strFile)
	Dim strFileContent
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT * FROM CLASS_LINK WHERE 1=1 " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		MakeHtmlLinkLogic = False
		Exit Function
	End If
	While Not GBL_objPubDB.objPubRS.Eof 
		If GBL_objPubDB.objPubRS("LINK_LOGO_SET") = 0 Then
			strFileContent = strFileContent & "<center><a href='" & GBL_objPubDB.objPubRS("LINK_URL") & "' title='" & GBL_objPubDB.objPubRS("LINK_DESC") & "' target=_blank>" & GBL_objPubDB.objPubRS("LINK_NAME") & "</a></center><br>"
		Else
			strFileContent = strFileContent & "<center><a href='" & GBL_objPubDB.objPubRS("LINK_URL") & "' title='" & GBL_objPubDB.objPubRS("LINK_DESC") & "' target=_blank><img align=absmiddle src='" & GBL_objPubDB.objPubRS("LINK_LOGO_IMG") & "' border=0 alt='" & GBL_objPubDB.objPubRS("LINK_DESC") & "'></center><br>"
		End If
		GBL_objPubDB.objPubRS.MoveNext
	Wend
	
	Call fsoWriteToFile(strFileContent,strFile,10)

	MakeHtmlLinkLogic = True
End Function

''===================================================================
'= Function    : SaveAboutLogic()
'= Time		   : Created At 2006-7-6
'= Return      : boolean
'= Description : save校友录介绍
'==================================================================='
Function SaveAboutLogic(strType,objFormData)
	GBL_objPubDB.Clear()
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.TableName = "CLASS_ABOUT"
	GBL_objPubDB.AddField strType,objFormData.Item("Content")
	If Not GBL_objPubDB.SQLRSExecute() Then
		SaveAboutLogic = False
		Exit Function
	End If

	If Not LoadParaLogic() Then Exit Function

	SaveAboutLogic = True

End Function

''===================================================================
'= Function    : SaveConfigLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intAdminId :  操作管理员 ID
'= Input	   : objFormData :  表单数据
'= Return      : boolean
'= Description : 保存网站信息
'==================================================================='
Function SaveConfigLogic(intAdminId,objFormData)

	GBL_objPubDB.Clear()
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.TableName = "CLASS_CONFIG"
	GBL_objPubDB.AddField "CONFIG_HOME_URL",objFormData.Item("HomeUrl")
	GBL_objPubDB.AddField "CONFIG_SITE_URL",objFormData.Item("SiteUrl")
	GBL_objPubDB.AddField "CONFIG_EMAIL",objFormData.Item("Email")
	GBL_objPubDB.AddField "CONFIG_CONTACT",objFormData.Item("Contact")
	GBL_objPubDB.AddField "CONFIG_RECORD",objFormData.Item("Record")
	GBL_objPubDB.AddField "CONFIG_COPY_RIGHT",objFormData.Item("CopyRight")
	GBL_objPubDB.AddField "CONFIG_CREATER", objFormData.Item("Creater")
	GBL_objPubDB.AddField "CONFIG_CREATE_TIME",objFormData.Item("CreateTime")
	GBL_objPubDB.AddField "CONFIG_SITE_NAME",objFormData.Item("SiteName")
	GBL_objPubDB.AddField "CONFIG_LAST_ADMIN_ID",intAdminId
	GBL_objPubDB.AddField "CONFIG_LAST_TIME",Now()
	If Not GBL_objPubDB.SQLRSExecute() Then
		SaveConfigLogic = False
		Exit Function
	End If

	'== 更新application数据
	If Not LoadParaLogic() Then
		SaveConfigLogic = False
		Exit Function
	End If
	SaveConfigLogic = True
End Function

''===================================================================
'= Function    : SaveSetupLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intAdminId :  操作管理员 ID
'= Input	   : objFormData :  表单数据
'= Return      : boolean
'= Description : 保存参数设置
'==================================================================='
Function SaveSetupLogic(intAdminId,objFormData)

	GBL_objPubDB.Clear()
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.TableName = "CLASS_SETUP"
	GBL_objPubDB.AddField "SETUP_ADMIN_PER_PAGE",objFormData.Item("AdminPerPage")
	GBL_objPubDB.AddField "SETUP_USER_PER_PAGE",objFormData.Item("UserPerPage")
	GBL_objPubDB.AddField "SETUP_ALBUM_SIZE",objFormData.Item("AlbumSize")

	GBL_objPubDB.AddField "SETUP_CCID",objFormData.Item("CCID")
	GBL_objPubDB.AddField "SETUP_LISTID",objFormData.Item("ListID")
	GBL_objPubDB.AddField "SETUP_CCBUTTON",objFormData.Item("CCButton")
	GBL_objPubDB.AddField "SETUP_OPEN_LIST",objFormData.Item("OpenList")

	GBL_objPubDB.AddField "SETUP_LAST_ADMIN_ID",intAdminId
	GBL_objPubDB.AddField "SETUP_LAST_TIME",Now()
	If Not GBL_objPubDB.SQLRSExecute() Then
		SaveSetupLogic = False
		Exit Function
	End If

	'== 更新application数据
	If Not LoadParaLogic() Then
		SaveSetupLogic = False
		Exit Function
	End If
	SaveSetupLogic = True
End Function

''===================================================================
'= Function    : LoadParaLogic()
'= Time		   : Created At 2006-5-5
'= Return      : boolean
'= Description : 装入网站参数到内容中
'==================================================================='
Function LoadParaLogic()
	Dim i

	'== load config
	If Not GetConfigLogic() Then
		LoadParaLogic = False
		Exit Function
	End If
	Application.Lock()
	Application(GBL_strCookieURL & "APP_strSiteName") = GBL_objPubDB.objPubRS("CONFIG_SITE_NAME")
	Application(GBL_strCookieURL & "APP_strSiteUrl") = GBL_objPubDB.objPubRS("CONFIG_SITE_URL")
	Application(GBL_strCookieURL & "APP_strHomeUrl") = GBL_objPubDB.objPubRS("CONFIG_HOME_URL")
	Application(GBL_strCookieURL & "APP_strRecord") = GBL_objPubDB.objPubRS("CONFIG_RECORD")
	Application(GBL_strCookieURL & "APP_strEmail") = GBL_objPubDB.objPubRS("CONFIG_EMAIL")
	Application(GBL_strCookieURL & "APP_strCopyRight") = GBL_objPubDB.objPubRS("CONFIG_COPY_RIGHT")
	Application.UnLock()

	'== load config
	If Not GetAboutLogic() Then
		LoadParaLogic = False
		Exit Function
	End If
	Application.Lock()
	Application(GBL_strCookieURL & "APP_strBoard") = GBL_objPubDB.objPubRS("ABOUT_BOARD")
	Application(GBL_strCookieURL & "APP_strReg") = GBL_objPubDB.objPubRS("ABOUT_REG")
	Application.UnLock()

	'== load setup
	If Not GetSetupLogic() Then
		LoadParaLogic = False
		Exit Function
	End If
	Application.Lock()
	Application(GBL_strCookieURL & "APP_intAdminPerPage") = 10
	Application(GBL_strCookieURL & "APP_intUserPerPage") = GBL_objPubDB.objPubRS("SETUP_USER_PER_PAGE")
	Application(GBL_strCookieURL & "APP_intUserReg") = GBL_objPubDB.objPubRS("SETUP_USER_REG")
	Application(GBL_strCookieURL & "APP_intUserRegQues") = GBL_objPubDB.objPubRS("SETUP_USER_REG_QUES")
	Application(GBL_strCookieURL & "APP_intAlbumSize") = GBL_objPubDB.objPubRS("SETUP_ALBUM_SIZE")


	Application(GBL_strCookieURL & "APP_strCCID") = GBL_objPubDB.objPubRS("SETUP_CCID")
	Application(GBL_strCookieURL & "APP_strListID") = GBL_objPubDB.objPubRS("SETUP_LISTID")
	Application(GBL_strCookieURL & "APP_strCCButton") = GBL_objPubDB.objPubRS("SETUP_CCBUTTON")
	Application(GBL_strCookieURL & "APP_strOpenList") = GBL_objPubDB.objPubRS("SETUP_OPEN_LIST")
	

	'== load time
	Application(GBL_strCookieURL & "APP_strLoadTime") = Now()

	'== load flag
	Application(GBL_strCookieURL & "APP_ConfigLoaded") = "Y" '==Y/N
	Application.UnLock()

	'== load forum master config
	If Not GetForumConfigLogic() Then
		LoadParaLogic = False
		Exit Function
	End If
	
	Dim strTmp1,strTmp2,strTmp3
	For i = 1 To GBL_objPubDB.intRSNum
		strTmp1 = strTmp1 & "|||Forum" & GBL_objPubDB.objPubRS("FORUM_ID") & "=" & GBL_objPubDB.objPubRS("FORUM_MASTER")
		strTmp2 = strTmp2 & "|||Forum" & GBL_objPubDB.objPubRS("FORUM_ID") & "=" & GBL_objPubDB.objPubRS("FORUM_MASTER_NAME")
		strTmp3 = strTmp3 & "|||Forum" & GBL_objPubDB.objPubRS("FORUM_ID") & "=" & GBL_objPubDB.objPubRS("FORUM_NAME") & "|" & GBL_objPubDB.objPubRS("FORUM_DES") & "|" & GBL_objPubDB.objPubRS("FORUM_ICO")
		GBL_objPubDB.objPubRS.MoveNext
	Next
	If Left(strTmp1,3) = "|||" Then
		strTmp1 = Right(strTmp1,Len(strTmp1) - 3)
	End If
	If Left(strTmp2,3) = "|||" Then
		strTmp2 = Right(strTmp2,Len(strTmp2) - 3)
	End If
	If Left(strTmp3,3) = "|||" Then
		strTmp3 = Right(strTmp3,Len(strTmp3) - 3)
	End If

	Application.Lock
	Application(GBL_strCookieURL & "FORUM_MASTER") = strTmp1
	Application(GBL_strCookieURL & "FORUM_MASTER_NAME") = strTmp2
	Application(GBL_strCookieURL & "FORUM_CATE") = strTmp3
	Application.UnLock

	'== 取贴吧分类记录
	Dim strTmpCateName,strTmpCateId,strTmpCateLink
	If Not GetForumCatesLogic() Then
		LoadParaLogic = False
		Exit Function
	End If
	
		While Not GBL_objPubDB.objPubRS.Eof
			strTmpCateName = strTmpCateName & "|||" & GBL_objPubDB.objPubRS("CATE_NAME")
			strTmpCateId = strTmpCateId & "|||" & GBL_objPubDB.objPubRS("CATE_ID")
			GBL_objPubDB.objPubRS.MoveNext
		Wend
	If Left(strTmpCateName,3) = "|||" Then
		strTmpCateName = Right(strTmpCateName,Len(strTmpCateName) - 3)
		strTmpCateId = Right(strTmpCateId,Len(strTmpCateId) - 3)
	End If
	Application.Lock
	Application(GBL_strCookieURL & "FORUM_CATE_NAME") = strTmpCateName
	Application(GBL_strCookieURL & "FORUM_CATE_ID") = strTmpCateId
	Application(GBL_strCookieURL & "FORUM_CATE_LINK") = strTmpCateLink
	Application.Unlock()

	'== 取得贴吧总版主
	GBL_objPubDB.Clear()
	GBL_objPubDB.ALLSQL = "SELECT USER_ACCOUNT,USER_ID,USER_REALNAME FROM CLASS_USER WHERE USER_AUTHEN=1"
	If Not GBL_objPubDB.SQLRSExecute() Then
		LoadParaLogic = False
		Exit Function
	End If
	Dim strMaster,strAccount,strId
	While Not GBL_objPubDB.objPubRS.Eof
		strMaster = strMaster & "|||" & GBL_objPubDB.objPubRS("USER_REALNAME")	
		strAccount = strAccount & "|||" & GBL_objPubDB.objPubRS("USER_ACCOUNT")
		strId = strId & "|||" & GBL_objPubDB.objPubRS("USER_ID")
		GBL_objPubDB.objPubRS.MoveNext
	Wend
	Application.Lock
	Application(GBL_strCookieURL & "strForumMasterName") = strMaster
	Application(GBL_strCookieURL & "strForumMasterAccount") = strAccount
	Application(GBL_strCookieURL & "strForumMasterId") = strId
	Application.Unlock()
	
	LoadParaLogic = True
End Function

%>