www.gusucode.com > CC校友录贴吧 CCBar源码程序asp编程 > inc/logic/logic_meet.asp

    <%
''===================================================================
'= ASP FILENAME	: /inc/logic/logic_meet.asp
'= CREATED TIME : 2006-5-1
'= LAST MODIFIED: 2006-5-1
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 聚会处理逻辑
'= Change Log:
'==================================================================='
%>

<%
'== meet over/run
Const CONST_MEET_OVER = 1
Const CONST_MEET_RUN = 0
Const CONST_MEET_LOGO = "meet_logo.gif"

''===================================================================
'= Function    : GetMeetsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : 符合条件
'= Return      : boolean
'= Description : 取聚会记录集
'==================================================================='
Function GetMeetsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_ID, USER_ACCOUNT,USER_REALNAME,MEET_ID,MEET_TIME,MEET_ADD_TIME,MEET_TYPE,MEET_STATUS,MEET_BBS_NUM,MEET_TITLE FROM CLASS_USER,CLASS_MEET WHERE MEET_OWNER_ID=USER_ID " & strWhere & " ORDER BY MEET_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetMeetsLogic = False
		Exit Function
	End If
	GetMeetsLogic = True
End Function

''===================================================================
'= Function    : GetMeetLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 取聚会记录
'==================================================================='
Function GetMeetLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_ID,USER_REALNAME,MEET_SPOT,MEET_AREA,MEET_SPEND,MEET_PEOPLE_NUM,MEET_CONTACT,MEET_INTRO,MEET_OTHER,MEET_SUM,MEET_ID,MEET_TIME,MEET_ADD_TIME,MEET_TYPE,MEET_STATUS,MEET_BBS_NUM,MEET_TITLE FROM CLASS_USER,CLASS_MEET WHERE MEET_OWNER_ID=USER_ID " & strWhere & " ORDER BY MEET_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetMeetLogic = False
		Exit Function
	End If
	GetMeetLogic = True
End Function

''===================================================================
'= Function    : GetMeetBBSsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 取聚会留言记录集
'==================================================================='
Function GetMeetBBSsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_REALNAME,USER_ID,MEET_BBS_ID,MEET_BBS_TIME,MEET_BBS_TITLE,MEET_BBS_CONTENT,MEET_BBS_MEET_ID FROM CLASS_USER,CLASS_MEET_BBS WHERE MEET_BBS_OWNER_ID=USER_ID " & strWhere & " ORDER BY MEET_BBS_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetMeetBBSsLogic = False
		Exit Function
	End If
	GetMeetBBSsLogic = True
End Function

''===================================================================
'= Function    : GetMeetJoinsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 聚会ID
'= Return      : boolean
'= Description : 取聚会报名记录集
'==================================================================='
Function GetMeetJoinsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_REALNAME,MEET_JOIN_STATUS,MEET_JOIN_OWNER,USER_ID,MEET_JOIN_ID,MEET_JOIN_TIME,MEET_JOIN_CONTACT FROM CLASS_USER,CLASS_MEET_JOIN WHERE MEET_JOIN_OWNER_ID=USER_ID " & strWhere & " ORDER BY MEET_JOIN_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetMeetJoinsLogic = False
		Exit Function
	End If
	GetMeetJoinsLogic = True
End Function

''===================================================================
'= Function    : RemoveMeetsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description :  删除聚会
'==================================================================='
Function RemoveMeetsLogic(strWhere)
	Dim strSql
	strSql = " AND MEET_JOIN_MEET_ID IN (SELECT MEET_ID FROM CLASS_MEET WHERE 1=1 " & strWhere & ")"
	'== 删除报名
	If Not RemoveMeetJoinsLogic(strSql) Then
		RemoveMeetsLogic = False
		Exit Function
	End If

	'== 删除留言
	strSql = " AND MEET_BBS_MEET_ID IN (SELECT MEET_ID FROM CLASS_MEET WHERE 1=1 " & strWhere & ")"
	If Not RemoveMeetBBSsLogic(strSql) Then
		RemoveMeetsLogic = False
		Exit Function
	End If

	'== 删除本身
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere 
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveMeetsLogic = False
		Exit Function
	End If
	RemoveMeetsLogic = True
End Function

''===================================================================
'= Function    : RemoveMeetBBSsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description :  删除聚会留言
'==================================================================='
Function RemoveMeetBBSsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET_BBS"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere 
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveMeetBBSsLogic = False
		Exit Function
	End If
	RemoveMeetBBSsLogic = True
End Function

''===================================================================
'= Function    : RemoveMeetJoinsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 删除聚会报名
'==================================================================='
Function RemoveMeetJoinsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET_JOIN"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere 
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveMeetJoinsLogic = False
		Exit Function
	End If
	RemoveMeetJoinsLogic = True
End Function

''===================================================================
'= Function    : SaveMeetLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intMeetId : 聚会ID
'= Return      : boolean
'= Description : 保存聚会信息
'==================================================================='
Function SaveMeetLogic(intMeetId,intUserId,objFormData)
	Dim strTitle,strStatus,strType,strArea,strSpot,strSpend,strTime,strPeopleNum,strContact,strSum,strContent,strOther

	strTitle = objFormData.Item("Title")
	If intMeetId <> "" Then
		strStatus = objFormData.Item("Status")
	Else
		strStatus = CONST_MEET_RUN
	End If
	strType = objFormData.Item("Type")
	strArea = objFormData.Item("Area")
	strSpot = objFormData.Item("Spot")
	strSpend = objFormData.Item("Spend")
	strTime = objFormData.Item("Time")
	strPeopleNum = objFormData.Item("PeopleNum")
	strContact = objFormData.Item("Contact")
	strSum = objFormData.Item("Sum")
	strContent = objFormData.Item("Content")
	strOther = objFormData.Item("Other")

	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET"
	If intMeetId <> "" Then
		GBL_objPubDB.SQLType = "UPDATE"
	Else
		GBL_objPubDB.SQLType = "INSERT"
		GBL_objPubDB.AddField "MEET_OWNER_ID",intUserId
		GBL_objPubDB.AddField "MEET_LOGO",CONST_MEET_LOGO
		GBL_objPubDB.AddField "MEET_ADD_TIME",Now()
	End If

	GBL_objPubDB.AddField "MEET_TITLE",strTitle
	GBL_objPubDB.AddField "MEET_INTRO",strContent
	GBL_objPubDB.AddField "MEET_OTHER",strOther
	GBL_objPubDB.AddField "MEET_SUM",strSum
	GBL_objPubDB.AddField "MEET_TIME",strTime
	GBL_objPubDB.AddField "MEET_SPOT",strSpot
	GBL_objPubDB.AddField "MEET_AREA",strArea
	GBL_objPubDB.AddField "MEET_SPEND",strSpend
	GBL_objPubDB.AddField "MEET_CONTACT",strContact
	GBL_objPubDB.AddField "MEET_PEOPLE_NUM",strPeopleNum
	GBL_objPubDB.AddField "MEET_TYPE",strType
	GBL_objPubDB.AddField "MEET_STATUS",strStatus
	GBL_objPubDB.AddField "MEET_LAST_TIME",Now()
	If intMeetId <> "" Then
		GBL_objPubDB.Where = " MEET_ID=" & intMeetId
	End If
	If Not GBL_objPubDB.SQLExecute() Then
		SaveMeetLogic = False
		Exit Function
	End If
	SaveMeetLogic = True
End Function

''===================================================================
'= Function    : GetMeetStatusLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intStatus : 聚会状态数字
'= Return      : 聚会状态中文含义
'= Description : 取得聚会状态
'==================================================================='
Function GetMeetStatusLogic(intStatus)
	If Cint(intStatus) = CONST_MEET_RUN Then
		GetMeetStatusLogic = "召集中"
	Else
		GetMeetStatusLogic = "已结束"
	End If
End Function

''===================================================================
'= Function    : GetLastNextMeetIdLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intAlbumId 
'= Output	   : intLastId 
'= Output	   : intNextId 
'= Return      : boolean
'= Description : 取得上一张下一张ID
'==================================================================='
Function GetLastNextMeetIdLogic(intAlbumId,ByRef intLastId,intNextId)
	intLastId = GetNextRS("MEET_ID","CLASS_MEET","MEET_ID>" & intAlbumId,"MEET_ID ASC")
	intNextId = GetNextRS("MEET_ID","CLASS_MEET","MEET_ID<" & intAlbumId,"MEET_ID DESC")
End Function

''===================================================================
'= Function    : SaveMeetJoinLogic()
'= Time		   : Created At 2006-5-7
'= Input	   : intUserId 
'= Input	   : objFormData 
'= Return      : boolean
'= Description : 用户聚会报名
'==================================================================='
Function SaveMeetJoinLogic(intUserId,intMeetId,objFormData)
	'== 已停止的聚会不能报名
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "MEET_STATUS",""
	GBL_objPubDB.Where =  " MEET_ID=" & intMeetId & " AND MEET_STATUS=" & CONST_MEET_OVER
	If Not GBL_objPubDB.SQLRSExecute() Then
		SaveMeetJoinLogic = False
		Exit Function
	End If
	If GBL_objPubDB.intRSNum > 0 Then
		Call GBL_objException.catchErr(E_USER_PUB,"已停止的聚会不能报名")
	End If

	'==删除老的报名记录
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET_JOIN"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where =  "MEET_JOIN_OWNER_ID=" & intUserId & " AND MEET_JOIN_STATUS=0 AND MEET_JOIN_MEET_ID=" & intMeetId
	If Not GBL_objPubDB.SQLExecute() Then
		SaveMeetJoinLogic = False
		Exit Function
	End If

	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET_JOIN"
	GBL_objPubDB.SQLType = "INSERT"
	GBL_objPubDB.AddField "MEET_JOIN_OWNER",objFormData.Item("User")
	GBL_objPubDB.AddField "MEET_JOIN_CONTACT",objFormData.Item("Tel")
	GBL_objPubDB.AddField "MEET_JOIN_OWNER_ID",intUserId
	GBL_objPubDB.AddField "MEET_JOIN_STATUS",0
	GBL_objPubDB.AddField "MEET_JOIN_MEET_ID",intMeetId
	If Not GBL_objPubDB.SQLExecute() Then
		SaveMeetJoinLogic = False
		Exit Function
	End If
	SaveMeetJoinLogic = True
End Function

''===================================================================
'= Function    : SaveMeetBBSLogic()
'= Time		   : Created At 2006-5-7
'= Input	   : intUserId 
'= Input	   : intMeetId 
'= Input	   : objFormData 
'= Return      : boolean
'= Description : 保存聚会留言
'==================================================================='
Function SaveMeetBBSLogic(intUserId,intMeetId,objFormData)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET_BBS"
	GBL_objPubDB.SQLType = "INSERT"
	GBL_objPubDB.AddField "MEET_BBS_OWNER_ID",intUserId
	GBL_objPubDB.AddField "MEET_BBS_CONTENT",objFormData.Item("Content")
	GBL_objPubDB.AddField "MEET_BBS_MEET_ID",intMeetId
	If Not GBL_objPubDB.SQLExecute() Then
		SaveMeetBBSLogic = False
		Exit Function
	End If
	SaveMeetBBSLogic = True
End Function
%>