www.gusucode.com > CC校友录贴吧 CCBar源码程序asp编程 > inc/logic/logic_user.asp

    <%
''===================================================================
'= ASP FILENAME	: /inc/logic/logic_user.asp
'= CREATED TIME : Feb,08,2004
'= LAST MODIFIED: Feb,08,2004
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用户处理逻辑
'= Change Log:
'==================================================================='
%>

<%
''===================================================================
'= Function    : GetUsersLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 取用户记录集
'==================================================================='
Function GetUsersLogic(strWhere)
	GBL_objPubDB.Clear()
	If Instr(strWhere,"ORDER BY") > 0 Then
		GBL_objPubDB.AllSQL = "SELECT * FROM CLASS_USER WHERE 1=1 " & strWhere
	Else
	GBL_objPubDB.AllSQL = "SELECT * FROM CLASS_USER WHERE 1=1 " & strWhere & "ORDER BY USER_ID DESC"
	End If
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetUsersLogic = False
		Exit Function
	End If
	GetUsersLogic = True
End Function

''===================================================================
'= Function    : GetUserLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 取用户记录
'==================================================================='
Function GetUserLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_QQ,USER_AUTHEN,USER_CLASS,USER_QUESTION,USER_ANSWER,USER_WORK,USER_SEX,USER_LEVEL,USER_BOARD,USER_INFO,USER_TOPICS,USER_PHOTO,USER_REPLY,USER_REVIEW,USER_LOGIN_COUNT,USER_ENROLL,USER_LAST_IP,USER_WORKSHOP,USER_ADDRESS,USER_GRAD,USER_EMAIL,USER_TELE,USER_ADD_DATE,USER_LAST_TIME,USER_BIRTH,USER_REALNAME,USER_NOW_FACE,USER_FACE_SELECT,USER_ACCOUNT,USER_ID FROM CLASS_USER WHERE 1=1" & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetUserLogic = False
		Exit Function
	End If
	GetUserLogic = True
End Function

''===================================================================
'= Function    : GetUserFaceSetLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 用户ID
'= Return      : boolean
'= Description : 取得用户签名图
'==================================================================='
Function GetUserFaceSetLogic(intUserId)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "USER_FACE_SELECT",""
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetUserFaceSetLogic = False
		Exit Function
	End If
	GetUserFaceSetLogic = True
End Function

''===================================================================
'= Function    : SaveUserFaceSetLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 用户ID
'= Input	   : objFormData : 表单数据
'= Return      : boolean
'= Description : 保存用户首选签名图设置
'==================================================================='
Function SaveUserFaceSetLogic(intUserId,objFormData)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "USER_FACE_SELECT",objFormData.Item("FaceSet")
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	If Not GBL_objPubDB.SQLExecute() Then
		SaveUserFaceSetLogic = False
		Exit Function
	End If
	If Not ChgUserFaceLogic(intUserId) Then
		SaveUserFaceSetLogic = False
		Exit Function
	End If
	SaveUserFaceSetLogic = True
End Function

''===================================================================
'= Function    : SaveUserCartoonLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 用户ID
'= Input	   : objFormData : 表单数据
'= Return      : boolean
'= Description : 保存用户卡通签名设置
'==================================================================='
Function SaveUserCartoonLogic(intUserId,objFormData)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "USER_CARTOON_FACE",objFormData.Item("CartoonFace")
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	If Not GBL_objPubDB.SQLExecute() Then
		SaveUserCartoonLogic = False
		Exit Function
	End If
	If Not ChgUserFaceLogic(intUserId) Then
		SaveUserCartoonLogic = False
		Exit Function
	End If
	SaveUserCartoonLogic = True
End Function

''===================================================================
'= Function    : GetUserCartoonLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 用户ID
'= Return      : boolean
'= Description : 取得用户签名图及qq
'==================================================================='
Function GetUserCartoonLogic(intUserId)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "USER_CARTOON_FACE,USER_QQ",""
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetUserCartoonLogic = False
		Exit Function
	End If
	GetUserCartoonLogic = True
End Function

''===================================================================
'= Function    : ChgUserFaceLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 用户ID
'= Return      : boolean
'= Description : 修改用户签名图
'==================================================================='
Function ChgUserFaceLogic(intUserId)
	Dim strNowFace,strFaceSet

	ChgUserFaceLogic = True
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "USER_FACE_SELECT,USER_QQ,USER_CARTOON_FACE,USER_UP_FACE",""
	GBL_objPubDB.Where = "USER_ID=" & intUserId 
	If Not GBL_objPubDB.SQLRSExecute() Then		
		ChgUserFaceLogic = False
		Exit Function
	End If

	strFaceSet = GBL_objPubDB.objPubRS("USER_FACE_SELECT")
	If strFaceSet = "个人头像" Then
		strNowFace =_
			GBL_strUserUpFace & GBL_objPubDB.objPubRS("USER_UP_FACE")
	ElseIf strFaceSet = "QQ秀" Then
		strNowFace =_
			MakeQQShow(GBL_objPubDB.objPubRS("USER_QQ"))
	Else
		strNowFace =_
			GBL_strCartoonFacePath & GBL_objPubDB.objPubRS("USER_CARTOON_FACE") & ".gif"
	End If

	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	GBL_objPubDB.AddField "USER_NOW_FACE",strNowFace
	If Not GBL_objPubDB.SQLExecute() Then
		ChgUserFaceLogic = False
		Exit Function
	End If
	ChgUserFaceLogic = True
End Function

''===================================================================
'= Function    : GetUserAuthLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intAuth : 
'= Return      : 用户身份的中文含义
'= Description : 取得用户身份
'==================================================================='
Function GetUserAuthLogic(intAuth)
	Dim strTmp
	Select Case Cint(intAuth)
		Case	0	: strTmp = "普通成员"
		Case	1	: strTmp = "管理员"
		Case	2	: strTmp = "副管理员"
		Case	3	: strTmp = "未通过认证的新用户"
		Case	4	: strTmp = "锁定用户"
		Case	Else : strTmp = "不明用户"
	End Select
	GetUserAuthLogic = strTmp
End Function

''===================================================================
'= Function    : RemoveUsersLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strIds : 
'= Return      : 用户身份的中文含义
'= Description : 删除用户
'==================================================================='
Function RemoveUsersLogic(strIds)
	'== Delete this user's board
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_BOARD"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "BOARD_USER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	'== Delete this user's review
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM_REVIEW"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "ALBUM_REVIEW_OWNER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	'== Delete this user's album
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "ALBUM_OWNER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	'== Delete this user's bbs reply
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_REPLY"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "REPLY_OWNER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	'== Delete this user's bbs topics
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_TOPICS"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "TOPICS_OWNER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	'== Delete this user's meeting
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "MEET_OWNER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	'== Delete this user's meeting bbs
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET_BBS"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "MEET_BBS_OWNER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	'== Delete this meet join
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_MEET_JOIN"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "MEET_JOIN_OWNER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	'== Delete this user's sms
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SMS"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "SMS_INCEPTER_ID IN (" & strIds  & ") OR SMS_SENDER_ID IN (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If
	
	'== 最后删除用户
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = "USER_ID In (" & strIds & ")"
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveUsersLogic = False
		Exit Function
	End If

	RemoveUsersLogic = True
End Function

''===================================================================
'= Function    : AccUsersLogic()
'= Time		   : Created At 2006-7-1
'= Input	   : strIds : 
'= Return      : boolean
'= Description : 批准用户
'==================================================================='
Function AccUsersLogic(strIds)
	
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "USER_AUTHEN",0
	GBL_objPubDB.Where = "USER_ID In (" & strIds & ") AND USER_AUTHEN=8 "
	If Not GBL_objPubDB.SQLRSExecute() Then
		AccUsersLogic = False
		Exit Function
	End If

	AccUsersLogic = True
End Function

''===================================================================
'= Function    : MasterUsersLogic()
'= Time		   : Created At 2006-7-1
'= Input	   : strIds : 
'= Return      : boolean
'= Description : 设置用户为贴吧总版主
'==================================================================='
Function MasterUsersLogic(strIds)
	
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "USER_AUTHEN",1
	GBL_objPubDB.Where = "USER_ID In (" & strIds & ") AND USER_AUTHEN=0 "
	If Not GBL_objPubDB.SQLRSExecute() Then
		MasterUsersLogic = False
		Exit Function
	End If

	MasterUsersLogic = True
End Function

''===================================================================
'= Function    : UnMasterUsersLogic()
'= Time		   : Created At 2006-7-1
'= Input	   : strIds : 
'= Return      : boolean
'= Description : 解除设置用户为贴吧总版主
'==================================================================='
Function UnMasterUsersLogic(strIds)
	
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "USER_AUTHEN",0
	GBL_objPubDB.Where = "USER_ID In (" & strIds & ") AND USER_AUTHEN=1 "
	If Not GBL_objPubDB.SQLRSExecute() Then
		UnMasterUsersLogic = False
		Exit Function
	End If

	UnMasterUsersLogic = True
End Function

''===================================================================
'= Function    : GetUserSmsNumLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 
'= Output	   : intSms : 短信数
'= Return      : boolean
'= Description : 用户短信数
'==================================================================='
Function GetUserSmsNumLogic(intUserId,ByRef intSms)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SMS"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.Where = "SMS_INCEPTER_ID=" & intUserId & " AND SMS_SEND_FLAG=1 AND SMS_DEL_INCEPT=0"
	GBL_objPubDB.AddField "SMS_ID",""
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetUserSmsNumLogic = False
		Exit Function
	End If
	intSms = GBL_objPubDB.intRSNum 
	GetUserSmsNumLogic = True
End Function

''===================================================================
'= Function    : GetUserNewSmsNumLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 
'= Output	   : intNewSms : 新短信数
'= Return      : boolean
'= Description : 用户新短信数
'==================================================================='
Function GetUserNewSmsNumLogic(intUserId,ByRef intNewSms)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SMS"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.Where = "SMS_INCEPTER_ID=" & intUserId & " AND SMS_SEND_FLAG=1 AND SMS_DEL_INCEPT=0 AND SMS_VIEW_FLAG=0"
	GBL_objPubDB.AddField "SMS_ID",""
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetUserNewSmsNumLogic = False
		Exit Function
	End If
	intNewSms = GBL_objPubDB.intRSNum 
	GetUserNewSmsNumLogic = True
End Function

''===================================================================
'= Function    : StatisticsUserDataLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strMethod : 
'= Output	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 统计用户数据
'==================================================================='
Function StatisticsUserDataLogic(strMethod,strWhere)
	Dim intNum,arrTmp,i
	If strMethod = "board" Then
		GBL_objPubDB.Clear()
		GBL_objPubDB.AllSQL = "SELECT BOARD_USER_ID,COUNT(BOARD_USER_ID) FROM CLASS_BOARD WHERE 1=1 " & strWhere & " GROUP BY BOARD_USER_ID ORDER BY BOARD_USER_ID DESC"
		If Not GBL_objPubDB.SQLRSExecute() Then
			StatisticsUserDataLogic = False
			Exit Function
		End If
		intNum = GBL_objPubDB.intRsNum
		arrTmp = GBL_objPubDB.objPubRS.GetRows(-1)
		For i = 0 To intNum -1
			GBL_objPubDB.Clear()
			GBL_objPubDB.AllSQL = "UPDATE CLASS_USER SET USER_BOARD=" & arrTmp(1,i) & " WHERE USER_ID=" & arrTmp(0,i)
			If Not GBL_objPubDB.SQLRSExecute() Then
				StatisticsUserDataLogic = False
				Exit Function
			End If
		Next
	End If

	If strMethod = "album" Then
		GBL_objPubDB.Clear()
		GBL_objPubDB.AllSQL = "SELECT ALBUM_OWNER_ID,COUNT(ALBUM_OWNER_ID) FROM CLASS_ALBUM WHERE 1=1 " & strWhere & " GROUP BY ALBUM_OWNER_ID ORDER BY ALBUM_OWNER_ID DESC"
		If Not GBL_objPubDB.SQLRSExecute() Then
			StatisticsUserDataLogic = False
			Exit Function
		End If		
		intNum = GBL_objPubDB.intRsNum
		arrTmp = GBL_objPubDB.objPubRS.GetRows(-1)
		For i = 0 To intNum -1
			GBL_objPubDB.Clear()
			GBL_objPubDB.AllSQL = "UPDATE CLASS_USER SET USER_PHOTO=" & arrTmp(1,i) & " WHERE USER_ID=" & arrTmp(0,i)
			If Not GBL_objPubDB.SQLRSExecute() Then
				StatisticsUserDataLogic = False
				Exit Function
			End If
		Next

		GBL_objPubDB.Clear()
		GBL_objPubDB.AllSQL = "SELECT ALBUM_REVIEW_OWNER_ID,COUNT(ALBUM_REVIEW_OWNER_ID) FROM CLASS_ALBUM_REVIEW GROUP BY ALBUM_REVIEW_OWNER_ID ORDER BY ALBUM_REVIEW_OWNER_ID DESC"
		If Not GBL_objPubDB.SQLRSExecute() Then
			StatisticsUserDataLogic = False
			Exit Function
		End If	
		intNum = GBL_objPubDB.intRsNum
		arrTmp = GBL_objPubDB.objPubRS.GetRows(-1)
		For i = 0 To intNum -1
			GBL_objPubDB.Clear()
			GBL_objPubDB.AllSQL = "UPDATE CLASS_USER SET USER_REVIEW=" & arrTmp(1,i) & " WHERE USER_ID=" & arrTmp(0,i)
			If Not GBL_objPubDB.SQLRSExecute() Then
				StatisticsUserDataLogic = False
				Exit Function
			End If	
		Next

	End If

	If strMethod = "forum" Then
		GBL_objPubDB.Clear()
		GBL_objPubDB.AllSQL = "SELECT TOPICS_OWNER_ID,COUNT(TOPICS_OWNER_ID) FROM CLASS_TOPICS WHERE 1=1 " & strWhere & " GROUP BY TOPICS_OWNER_ID ORDER BY TOPICS_OWNER_ID DESC"
		If Not GBL_objPubDB.SQLRSExecute() Then
			StatisticsUserDataLogic = False
			Exit Function
		End If	
		intNum = GBL_objPubDB.intRsNum
		arrTmp = GBL_objPubDB.objPubRS.GetRows(-1)
		For i = 0 To intNum -1
			GBL_objPubDB.Clear()
			GBL_objPubDB.AllSQL = "UPDATE CLASS_USER SET USER_TOPICS=" & arrTmp(1,i) & " WHERE USER_ID=" & arrTmp(0,i)
			If Not GBL_objPubDB.SQLRSExecute() Then
				StatisticsUserDataLogic = False
				Exit Function
			End If	
		Next

		GBL_objPubDB.Clear()
		GBL_objPubDB.AllSQL = "SELECT REPLY_OWNER_ID,COUNT(REPLY_OWNER_ID) FROM CLASS_REPLY GROUP BY REPLY_OWNER_ID ORDER BY REPLY_OWNER_ID DESC"
		If Not GBL_objPubDB.SQLRSExecute() Then
			StatisticsUserDataLogic = False
			Exit Function
		End If	
		intNum = GBL_objPubDB.intRsNum
		arrTmp = GBL_objPubDB.objPubRS.GetRows(-1)
		For i = 0 To intNum -1
			GBL_objPubDB.Clear()
			GBL_objPubDB.AllSQL = "UPDATE CLASS_USER SET USER_REPLY=" & arrTmp(1,i) & " WHERE USER_ID=" & arrTmp(0,i)
			If Not GBL_objPubDB.SQLRSExecute() Then
				StatisticsUserDataLogic = False
				Exit Function
			End If	
		Next
	End If

	If strMethod = "level" Then
		GBL_objPubDB.Clear()
		GBL_objPubDB.AllSQL = "UPDATE CLASS_USER SET USER_LEVEL=(USER_BOARD*" & GBL_intBoardLevel & "+USER_PHOTO*" & GBL_intAlbumLevel & "+USER_REVIEW*" & GBL_intReviewLevel & "+USER_TOPICS*" & GBL_intTopicsLevel & "+USER_REPLY*" & GBL_intReplyLevel &"+USER_LOGIN_COUNT*" & GBL_intLoginLevel & ") WHERE 1=1 " & strWhere 
		If Not GBL_objPubDB.SQLRSExecute() Then
			StatisticsUserDataLogic = False
			Exit Function
		End If	
	End If

	StatisticsUserDataLogic = True
End Function

''===================================================================
'= Function    : SaveUserLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 
'= Output	   : objFormData : 表单数据
'= Return      : boolean
'= Description : 保存用户信息
'==================================================================='
Function SaveUserLogic(intUserId,objFormData)
	Dim strBirth,strBirthYear,strBirthMon,strBirthDay

	If objFormData.Item("Grad") < objFormData.Item("Enroll") Then
		Call GBL_objException.catchErr(E_USER_PUB,"请填入正确的毕业和入学年份")
		SaveUser = False
		Exit Function
	End If

	strBirthYear = objFormData.Item("BirthYear")
	strBirthMon = objFormData.Item("BirthMon")
	strBirthDay = objFormData.Item("BirthDay")
	strBirth = strBirthYear & "-" & strBirthMon & "-" & strBirthDay

	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "USER_ID",""
	GBL_objPubDB.Where = "USER_EMAIL='" & objFormData.Item("Email") & "' AND USER_ID<>" & intUserId 
	If Not GBL_objPubDB.SQLRSExecute() Then
		Exit Function
	End If

	If GBL_objPubDB.intRSNum <> 0 Then
		SaveUserLogic = False
		Call GBL_objException.catchErr(E_USER_PUB,"该邮件地址已被人使用")
		Exit Function
	End If

	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	GBL_objPubDB.AddField "USER_EMAIL", objFormData.Item("Email")
	GBL_objPubDB.AddField "USER_REALNAME", objFormData.Item("RealName")
	GBL_objPubDB.AddField "USER_QUESTION", objFormData.Item("Question")
	GBL_objPubDB.AddField "USER_ANSWER", objFormData.Item("Answer")
	GBL_objPubDB.AddField "USER_QQ", objFormData.Item("Qq")
	GBL_objPubDB.AddField "USER_WORKSHOP", objFormData.Item("WorkShop")
	GBL_objPubDB.AddField "USER_TELE", objFormData.Item("Tele")
	GBL_objPubDB.AddField "USER_ADDRESS", objFormData.Item("Address")
	GBL_objPubDB.AddField "USER_CLASS", objFormData.Item("Class")
	GBL_objPubDB.AddField "USER_SEX", objFormData.Item("Sex")
	GBL_objPubDB.AddField "USER_BIRTH", strBirth
	GBL_objPubDB.AddField "USER_GRAD", objFormData.Item("Grad")
	GBL_objPubDB.AddField "USER_ENROLL", objFormData.Item("Enroll")
	GBL_objPubDB.AddField "USER_WORK", objFormData.Item("Work")
	GBL_objPubDB.AddField "USER_INFO",htmlencode2(objFormData.Item("Content"))
	If Not GBL_objPubDB.SQLExecute() Then
		SaveUserLogic = False
		Exit Function
	End If

	SaveUserLogic = True
End Function

''===================================================================
'= Function    : CheckUserPwdLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 
'= Output	   : objFormData : 表单数据
'= Return      : boolean
'= Description : 检验密码当前是否正确
'==================================================================='
Function CheckUserPwdLogic(intUserId,objFormData)
	Dim strOldPwd
	strOldPwd = objFormData.Item("OldPwd")
	strOldPwd = Md5(strOldPwd) 

	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	GBL_objPubDB.AddField "USER_PASSWORD", ""
	If Not GBL_objPubDB.SQLRSExecute() Then
		Exit Function
	End If
	If GBL_objPubDB.objPubRS("USER_PASSWORD") <> strOldPwd Then
		CheckUserPwdLogic = False
		Exit Function
	End If
	CheckUserPwdLogic = True
End Function

''===================================================================
'= Function    : SaveUserPwdLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 
'= Output	   : objFormData : 表单数据
'= Return      : boolean
'= Description : 修改用户密码
'==================================================================='
Function SaveUserPwdLogic(intUserId,objFormData)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	GBL_objPubDB.AddField "USER_PASSWORD", Md5(objFormData.Item("NewPwd"))
	If Not GBL_objPubDB.SQLExecute() Then
		SaveUserPwdLogic = False
		Exit Function
	End If
	SaveUserPwdLogic = True
End Function

''===================================================================
'= Function    : MakeHtmlUserOptionLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : strWhere 符合条件
'= Input	   : strFile  文件地址
'= Return      : boolean
'= Description : 生成用户select的option html文件
'==================================================================='
Function MakeHtmlUserOptionLogic(strWhere,strFile)
	Dim strFileContent
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.Where = "1=1 AND USER_AUTHEN<>8 " & strWhere
	GBL_objPubDB.AddField "USER_REALNAME", ""
	GBL_objPubDB.AddField "USER_ID", ""
	GBL_objPubDB.ORDER = "USER_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		MakeHtmlUserOptionLogic = False
		Exit Function
	End If
	While Not GBL_objPubDB.objPubRS.Eof 
		strFileContent = strFileContent & "<option value=""" & GBL_objPubDB.objPubRS("USER_ID") & """>" & GBL_objPubDB.objPubRS("USER_REALNAME") & "</option>" & chr(13) & chr(10)
		GBL_objPubDB.objPubRS.MoveNext
	Wend
	
	Call fsoWriteToFile(strFileContent,strFile,10)

	MakeHtmlUserOptionLogic = True
End Function

''===================================================================
'= Function    : MakeQQShow()
'= Time		   : Created At 2006-6-24
'= Input	   : intQQ
'= Return      : string
'= Description : qq url
'==================================================================='
Function MakeQQShow(intQQ)

	MakeQQShow = "http://qqshow-user.tencent.com/" & intQQ & "/10/00/"

End Function

''===================================================================
'= Function    : GetFriendLogic(strWhere)
'= Time		   : Created At 2006-6-24
'= Input	   : strWhere
'= Return      : string
'= Description : 
'==================================================================='
Function GetFriendLogic(strWhere)
	Dim strFileContent
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.Where = "1=1 " & strWhere
	GBL_objPubDB.AddField "USER_REALNAME", ""
	GBL_objPubDB.AddField "USER_ID", ""
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetFriendLogic = False
		Exit Function
	End If
	While Not GBL_objPubDB.objPubRS.Eof 
		strFileContent = strFileContent & "<option value=""" & GBL_objPubDB.objPubRS("USER_ID") & """>" & GBL_objPubDB.objPubRS("USER_REALNAME") & "</option>" & chr(13) & chr(10)
		GBL_objPubDB.objPubRS.MoveNext
	Wend
	
	Call fsoWriteToFile(strFileContent,strFile,10)

	GetFriendLogic = True
End Function

''===================================================================
'= Function    : SaveUserSignLogic(intUserId,strImg)
'= Time		   : Created At 2006-6-24
'= Input	   : intUserId
'= Input	   : strImg
'= Return      : boolean
'= Description : 用户签名图指定
'==================================================================='
Function SaveUserSignLogic(intUserId,strImg)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "USER_UP_FACE", GBL_objFormData.Item("UpFace")
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	If Not GBL_objPubDB.SQLExecute() Then
		SaveUserSignLogic = False
		Exit Function
	End If
	SaveUserSignLogic = True
End Function

''===================================================================
'= Function    : GetUserSignLogic(intUserId)
'= Time		   : Created At 2006-6-24
'= Input	   : intUserId
'= Input	   : strImg
'= Return      : boolean
'= Description : 用户签名图指定
'==================================================================='
Function GetUserSignLogic(intUserId,ByRef strUserSign)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "USER_UP_FACE", ""
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetUserSignLogic = False
		Exit Function
	End If
	strUserSign = GBL_objPubDB.objPubRS("USER_UP_FACE")
	GetUserSignLogic = True
End Function

''===================================================================
'= Function    : SaveUserPassLogic(intUserId)
'= Time		   : Created At 2006-6-24
'= Input	   : intUserId
'= Input	   : strImg
'= Return      : boolean
'= Description : 修改管理员用户密码
'==================================================================='
Function SaveUserPassLogic(intUserId,strPass)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_USER"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "USER_PASSWORD", Md5(strPass)
	GBL_objPubDB.Where = "USER_ID=" & intUserId
	If Not GBL_objPubDB.SQLExecute() Then
		SaveUserPassLogic = False
		Exit Function
	End If
	SaveUserPassLogic = True
End Function
%>