www.gusucode.com > 翼动留言板 2.1源码程序 > inc/Function.asp

    
<%
'************************************************************************************
'开发组		翼动工作室
'姓名		郑景德
'网名		旭日
'QQ			3178920
'个人网站		http://www.wingroom.com
'本页：
		'系统公用函数
'
'************************************************************************************

Class FunctionLib

    '函数:通用信息提示框
    '参数:
    '   提示内容
    '   返回地址,详细值类型如下:
    '       "#"      只提示，其它不做任何操作
    '       "BACK"   提示后返回前一页
    '       "CLOSE"  提示后关闭窗口
    '       "网址"    提示后返回指定页面
    '   是否父窗口
    Public Function Alert(str,backUrl,TopWindow)

        If str <> "" Then
            Response.Write "<script>alert(""" & str & """);"
        End If

        Dim WinName
        If TopWindow = 1 Then
            WinName = "top"
        Else
            WinName = "self"
        End If

        Select Case backUrl
            Case "#"
            Case "BACK"
                Response.Write WinName & ".history.back();"
            Case "CLOSE"
                Response.Write "window.close();"
            Case Else
                If backUrl <> "" Then
                    Response.Write WinName & ".location.href = """ & backUrl & """;"
                End If
        End Select
        Response.Write "</script>"
    End Function

	' ============================================
	' 格式化时间(显示)
	' 参数：n_Flag
	'	1:"yyyy-mm-dd hh:mm:ss"
	'	2:"yyyy-mm-dd"
	'	3:"hh:mm:ss"
	'	4:"yyyy年mm月dd日"
	' ============================================
	Public Function Format_Time(s_Time, n_Flag)
		Dim y, m, d, h, mi, s
		Format_Time = ""
		If IsDate(s_Time) = False Then Exit Function
		y = cstr(year(s_Time))
		m = cstr(month(s_Time))
		If len(m) = 1 Then m = "0" & m
		d = cstr(day(s_Time))
		If len(d) = 1 Then d = "0" & d
		h = cstr(hour(s_Time))
		If len(h) = 1 Then h = "0" & h
		mi = cstr(minute(s_Time))
		If len(mi) = 1 Then mi = "0" & mi
		s = cstr(second(s_Time))
		If len(s) = 1 Then s = "0" & s
		Select Case n_Flag
		Case 1
			' yyyy-mm-dd hh:mm:ss
			Format_Time = y & "-" & m & "-" & d & " " & h & ":" & mi & ":" & s
		Case 2
			' yyyy-mm-dd
			Format_Time = y & "-" & m & "-" & d
		Case 3
			' hh:mm:ss
			Format_Time = h & ":" & mi & ":" & s
		Case 4
			' yyyy年mm月dd日
			Format_Time = y & "年" & m & "月" & d & "日"
		End Select
	End Function

    '函数:验证邮件地址格式
    '参数:字符串
    '返回:bool (true:正确)
    Public Function CheckEmail(str)
        Dim regEx
        '创建正则对象
        Set regEx = New RegExp
        regEx.IgnoreCase = True
        regEx.Global = True
        regEx.MultiLine = True

        regEx.Pattern = "^\w+((-\w+)|(\.\w+))*\@[A-Za-z0-9]+((\.|-)[A-Za-z0-9]+)*\.[A-Za-z0-9]+$"
        CheckEmail = regEx.Test(str)
        Set regEx = Nothing
    End Function

    '函数:验证HTTP地址格式
    '参数:字符串
    '返回:bool (true:正确)
    Public Function CheckUrl(str)
        Dim regEx
        '创建正则对象
        Set regEx = New RegExp
        regEx.IgnoreCase = True
        regEx.Global = True
        regEx.MultiLine = True

        regEx.Pattern="^http:\/\/(.*?)"
        CheckUrl = regEx.Test(str)
        Set regEx = Nothing
    End Function

    '函数:验证QQ格式
    '参数:数字字符串
	'说明:目前QQ的位数和4-10
    '返回:bool (true:正确)
    Public Function CheckQQ(str)
        Dim regEx
        '创建正则对象
        Set regEx = New RegExp
        regEx.IgnoreCase = True
        regEx.Global = True
        regEx.MultiLine = True

        regEx.Pattern = "^\d{4,10}$"
        CheckQQ = regEx.Test(str)
        Set regEx = Nothing
    End Function

	'文档格式化输出
	Public Function outHTML(str)
		Dim sTemp
		sTemp = str
		outHTML = ""
		If IsNull(sTemp) = True Then
			Exit Function
		End If
		sTemp = Replace(sTemp, "&", "&amp;")
		sTemp = Replace(sTemp, "<", "&lt;")
		sTemp = Replace(sTemp, ">", "&gt;")
		sTemp = Replace(sTemp, Chr(34), "&quot;")
		sTemp = Replace(sTemp, Chr(32), "&nbsp;")
		sTemp = Replace(sTemp, Chr(10), "<br>")
		outHTML = sTemp
	End Function

	'Request安全过滤
	'作用：防SQL注入
	'Flag： 1[Str为数字型],2[Str为字符串]
	Public Function SaftSql(Str,Flag)
		SaftSql=Request(Str)
		If Flag=1 Then
			If Not IsNumeric(SaftSql) Or Trim(SaftSql)="" Then
				Response.Write("传入的参数不正确！")
				Response.End
			End If
		Else
			SaftSql=Replace(SaftSql,"'","''")
			SaftSql=Replace(SaftSql," ","")
		End If
	End Function

  ''字符串过滤
	Public Function FilterStr(Str)
		If Not Isempty(Str) and Str<>"" Then
			Str=replace(Str,"'","''")
			FilterStr=Str
		Else
			FilterStr=Empty
		End If
	End Function

End Class
%>