www.gusucode.com > 翼动留言板 2.1源码程序 > inc/ubbcode.asp

    <%
'************************************************************************************
'开发组		翼动工作室
'姓名		郑景德
'网名		旭日
'QQ			3178920
'个人网站		http://www.wingroom.com
'本页：
		'UBB函数
'
'************************************************************************************
Class FunctionUBB
	Public Function UBBCode(Content)
		If isEmpty(Content) Or isNull(Content) Then
			Exit Function
		Else
			Content = FilterStr(Content)
			Dim regEx,Matches,Match
			Set regEx=new RegExp
			regEx.IgnoreCase =True
			regEx.Global=True
			'加粗
			regEx.Pattern="\[b\](.*?)\[\/b\]"
			Content=regEx.Replace(Content,"<b>$1</b>")
			'倾斜的文字
			regEx.Pattern="\[i\](.*?)\[\/i\]"
			Content=regEx.Replace(Content,"<i>$1</i>")
			'下划线
			regEx.Pattern="\[u\](.*?)\[\/u\]"
			Content=regEx.Replace(Content,"<u>$1</u>")
			'文字居中
			regEx.Pattern="\[align=center\](.*?)\[\/align\]"
			Content=regEx.Replace(Content,"<div align=center>$1</div>")
			'超级链接
			regEx.Pattern="\[url=(http|https|ftp):\/\/(.*?)\](.*?)\[\/url\]"
			Content=regEx.Replace(Content,"<a href=""$1://$2"" target=_blank>$3</a>")
			'邮箱
			'[email]邮件地址[/email]
			regEx.Pattern="\[email\](\S+\@.[^\[]*)\[\/email\]"
			Content=regEx.Replace(Content,"<a href=""mailto:$1"">$1</a>")
			'[email=邮件地址]文字[/email]
			regEx.Pattern="\[email=(\S+\@.[^\[]*)\](.*?)\[\/email\]"
			Content=regEx.Replace(Content,"<a href=""mailto:$1"">$2</a>")
			'飞行字
			regEx.Pattern="\[fly\](.*)\[\/fly\]"
			Content=regEx.Replace(Content,"<marquee width=90% behavior=alternate scrollamount=5>$1</marquee>")
			regEx.Pattern="\[SHADOW=*([0-9]*),*(#*[a-z0-9]*),*([0-9]*)\](.[^\[]*)\[\/SHADOW]"
			Content=regEx.Replace(Content,"<table width=$1 style=""filter:shadow(color=$2, strength=$3)"">$4</table>")
			'图片
			regEx.Pattern="\[IMG\](http|https|ftp):\/\/(.[^\[]*)\[\/IMG\]"
			Content=regEx.Replace(Content,"<a onfocus=this.blur() href=""$1://$2"" target=_blank><IMG SRC=""$1://$2"" border=0 alt=按此在新窗口浏览图片 onload=""javascript:if(this.width>screen.width-333)this.width=screen.width-333""></a>")
			'表情图片
			regEx.Pattern="\[em(.[^\[]*)\]"
			Content=regEx.Replace(Content,"<img src=""images/em/em$1.gif"" border=0 align=middle>")
			Set regEx = Nothing
			UBBCode=Content
		End IF

	End Function
	'函数
	Public Function FilterStr(Content)
		Content = Replace(Content,"<","&lt;")
		Content = Replace(Content,">","&gt;")
		Content = Replace(Content,Chr(10),"<br>")
		Content = Replace(Content,Chr(32),"&nbsp;")
		Content = Replace(Content,Chr(9),"&nbsp;")
		Content = Replace(Content," ","&nbsp;")
		FilterStr = Content
	End Function

End Class
%>